Shell Programming and Scripting

The above code should be doing it already ...

You want 14 or 98 or 99

or

(14 or 98) and 99

or

14 and 98 and 99?

I want it "14 and 98 and 99". I'm so sorry but I'm new to array and looping, but I don't seem to understand the for (k in K) if ((K[k]<6) && (k in R)) part. Could you please elaborate further?

Code:

nawk '{ K[$1,$2,$3]++ }
$5 ~ /^(14|9[89])$/ && !t[$1,$2,$3,$5]++ {
T[$1,$2,$3]++
R[$1,$2,$3] = $1 FS $2 FS $3 FS $6
} END {
for (k in K)
 if ((K[k] < 6) && T[k] > 2)
   print R[k]
}' file

Thanks, radoulov but could you please explain your code further especially the for (k in K) if ((K[k]<6) && T[k] > 2) part? Cheers!

I corrected the code, the one you quoted is wrong.
(to be continued ... (will add the explanation later ))

Thanks radoulov! I'll wait for the explanation. Thanks for your patience in helping me out.

Code:

nawk '{ K[$1,$2,$3]++ }
$5 ~ /^(14|9[89])$/ && !t[$1,$2,$3,$5]++ {
T[$1,$2,$3]++
R[$1,$2,$3] = $1 FS $2 FS $3 FS $6
} END {
for (k in K)
 if ((K[k] < 6) && T[k] > 2)
   print R[k]
}' file

The explanation:

Code:

{ K[$1,$2,$3]++ }

K is an associative array (associative means keys are strings, not integers) populated with the unique values of the composite key $1 SUBSEP $2 SUBSEP $3, the elements contain the number of occurrences (the count) of these keys.

Code:

$5 ~ /^(14|9[89])$/ && !t[$1,$2,$3,$5]++

For each record that matches:
+ the pattern $5 == 14 or 98 or 99 AND
+ the composite key $1 SUBSEP $2 SUBSEP $3 SUBSEP $5 when seen for the first time (!t[$1,$2,$3,$5]++ is perhaps more readable as t[$1,$2,$3,$5]++ == 0)

Code:

{
T[$1,$2,$3]++
R[$1,$2,$3] = $1 FS $2 FS $3 FS $6
}

Count the occurrences of the key $1 SUBSEP $2 SUBSEP $3 (the T array) and save $1 FS $2 FS $3 FS $6 associated with the key $1 SUBSEP $2 SUBSEP $3 (the R array).

Code:

END {
for (k in K)
 if ((K[k] < 6) && T[k] > 2)
   print R[k]
}

After processing all the input iterate over the K array

Code:

for (k in K)

if the element (the number of occurrences) is less than 6 (a unique section) AND (logical) the element of the T array with the same key
(I used the same keys: $1,$2,$3) is greater than 2 (guarantees that
we have 14, 98 and 99 in the same section), print the element of the R array for that key.


Hope this helps.