Shell Programming and Scripting

ord,line,Date,Hour,count,appr
1217,1,11/19/2015,"00",8,""
1217,1,11/19/2015,"00",24,""
1217,1,11/19/2015,"08",4,""
1217,1,11/19/2015,"09",20,""
1217,1,11/19/2015,"10",42,""
1217,1,11/19/2015,"10",62,""
　

ord,line,Date,Hour,count,appr
1217,1,11/19/2015,"00",32,""
1217,1,11/19/2015,"08",4,""
1217,1,11/19/2015,"09",20,""
1217,1,11/19/2015,"10",104,""

awk '
function printlast() {
	if(last)
		print last, count, appr
	count = 0
}
BEGIN {	FS = OFS = ","
}
FNR == 1 {
	print
	next
}
last != $1 OFS $2 OFS $3 OFS $4 {
	printlast()
	last = $1 OFS $2 OFS $3 OFS $4
	appr = $6
}
{	count += $5
}
END {	printlast()
}' file

awk '
# Define function to print results for last aggregated data.
function printlast() {
	# If "last" is not empty (which will be true except for the first time
	# this function is called)...
	if(last)
		# print the results.
		print last, count, appr
	# Clear the accumulated count.
	count = 0
}
# Before reading any input files, set the input and output field separators to a
# comma.
BEGIN {	FS = OFS = ","
}
# When we are looking at the 1st line in an input file...
FNR == 1 {
	# copy the header line to the output...
	print
	# and skip to the next input line without execcuting the remaining lines
	# of this script for this line.
	next
}
# If "last" does not match the first four fields of the current input line...
last != $1 OFS $2 OFS $3 OFS $4 {
	# print the accumulated data for the previous line...
	printlast()
	# set "last" to the first four fields of the current input line...
	last = $1 OFS $2 OFS $3 OFS $4
	# and, set "appr" to the last field on this line.
	appr = $6
}
# Add the count from the current line to the total for lines matching "last".
{	count += $5
}
# After we have processed all lines from the input file, print the accumulated
# data for the last set of aggregated data.
END {	printlast()
}' file

ord,line,Date,Hour,count,appr
1217,1,11/19/2015,"00",8,""
1217,1,11/19/2015,"08",4,""
1217,1,11/19/2015,"10",62,""
1217,1,11/19/2015,"09",20,""
1217,1,11/19/2015,"00",24,""
1217,1,11/19/2015,"10",42,""

awk '
# Before reading any input files, set the input and output field separators to a
# comma.
BEGIN {	FS = OFS = ","
}
# When we are looking at the 1st line in an input file...
FNR == 1 {
	# Copy the header line to the output.
	print
	# and skip to the next input line without execcuting the remaining lines
	# of this script for this line.
	next
}
# Accumulate data form remaining lines in the file(s)...
{	# Set "key" to the first four input fields, accumulate the count (field
	# 5) from all lines with they key, and save the last appr field for each
	# key to be printed at the end.
	count[key = $1 OFS $2 OFS $3 OFS $4] += $5
	appr[key] = $6
}
# After we have processed all lines from the input file, print the accumulated
# data.
END {	for(key in count)
		print key, count[key], appr[key]
}' file