Shell Programming and Scripting

#!/bin/ksh
sf="syllables"
cf="corpus"
sample_max=10
awk -v sm="$sample_max" '
{	gsub(/\r/, "")
}
FNR == NR {
	# Read the list of syllables to be processed...
	len = length($1)
	if(NR == 1) 
		l = L = len
	else	if(l > len)
			l = len
		else if(L < len)
			L = len
	syl[len, ++lenc[len]] = $1
	next
}
{	# Accumulate data from dictionary entries...
	len = length(word = $1)
	for(i = (L > len) ? len : L; i >= l && len >= l; i--)
		for(j = 1; j <= lenc[i]; j++) {
			# If syllables we have matched leave fewer unmached
			# character in word than we are currently trying to
			# match, short circuit to a shorter syllable length...
			if(len < i)
				break
			s = syl[i, j]
			if(s == word) {
				# Process standalone match...
				++sa[s]
				len = 0
				if(sasc[s] < sm)
					sasam[s] = (sasc[s]++ ? \
					    sasam[s] "," : "\t") $0
			} else {if(sub("^"s, "\a", word)) {
					# Process initial match...
					++init[s]
					len -= i
					if(insc[s] < sm)
						insam[s] = (insc[s]++ ? \
						    insam[s] "," : "\t") $0
				}
				if(sub(s"$", "\a", word)) {
					# Process finish match...
					++fin[s]
					len -= i
					if(fisc[s] < sm)
						fisam[s] = (fisc[s]++ ? \
						    fisam[s] "," : "\t") $0
				}
				if(c = gsub(s, "\a", word)) {
					# Process medial matches...
					med[s] += c
					len -= c * i
					if(mesc[s] < sm)
						mesam[s] = (mesc[s]++ ? \
						    mesam[s] "," : "\t") $0
				}
			}
		}
}
END {	# Dump collected data...
	for(i = l; i <= L; i++) {
		for(j = 1; j <= lenc[i]; j++) {
			printf("%-11s %7s\n", (s = syl[i, j]) ":",
			    sa[s] + init[s] + fin[s] + med[s])
			printf("%-11s %7s%s\n", "Initial",
			    init[s] ? init[s] : "NONE", insam[s])
			printf("%-11s %7s%s\n", "Medial",
			    med[s] ? med[s] : "NONE", mesam[s])
			printf("%-11s %7s%s\n", "Final",
			    fin[s] ? fin[s] : "NONE", fisam[s])
			printf("%-11s %7s%s\n\n", "Standalone",
			    sa[s] ? sa[s] : "NONE", sasam[s])
		}
	}
}' "$sf" FS="[=]" "$cf"