Shell Programming and Scripting

Suppose I have a list of strings in a file called stringlist...

string1
string2
...
stringn

Suppose also that I have another file, or stdin, or whatever, and I want to use awk to see if some field in each record matches any string in stringlist. What I've been doing is using each string on the list as an index of an array isOnList, and the value of the array element is a unique string, like YUPPERS. This is in my BEGIN block:

Code:

while ("cat file_containing_strings" | getline)
     {
     isOnList[$1] = "YUPPERS"
     }

Suppose I'm interested in finding out whether, say, field 7 matches anything on the list. I have the list read into the array, so to do the testing in the body of my script, I simply do something like this:

Code:

isOnList[$7] == "YUPPERS"   {
     do some stuff...
     }

It works, and it seems reasonably efficient, but I wonder if there's a faster, less expensive way to do this. Looping through the array on each line can be pretty costly, I imagine. How would you all go about solving this sort of problem? Thanks.

They're supposed to be efficient when you use them like this. They're not straight arrays, they're some sort of hash or tree structure (implementation dependent).

You can get rid of the cat in BEGIN though -- in fact you can get rid of the BEGIN, just check for NR==FNR (line number in file equals total line number), which will only be true inside the first file awk reads...

And instead of checking for YUPPERS, check "if X in A" -- this is more efficient because it won't create a new array element whenever it finds an empty one.

Code:

awk 'NR==FNR { A[$1]=1 ; next }
$7 in A { some stuff }' stringlist datafile

and for the same reason, A[$1] alone defines an (empty) element; no reason to assign a value to it =1.

Hmm... say, that is pretty nice. And it's straightforward and easy. I like the use of FNR == NR. Thank you very much.