Shell Programming and Scripting

awk -F= '               # Set field separator to "="
# 1st two input files consist of pairs of lines using the format:
#               name=user
#               gud=value
# in this order.
# So with FS set to "=", $1 will be "name" or "gud" and $2 will be the name of
# the user or the value associated with that user name.

# 3rd input file consists of lines using the format:
#               user

# f     number of files seen
# lf    name of last file seen
# u     user from name=user line in 1st two input files
# r1[u] recorded value from 1st file from gud=value line for name u
# r2[u] recorded value from 2nd file from gud=value line for name u
FILENAME != lf {        # If this is the first time we have a line from this file
        f++             # increment the number of files seen and
        lf = FILENAME   # save the name of the current file for comparison.
}
$1 == "name" {          # If this is a name= line in 1 of the 1st 2 files,
        u = $2          # save the user name, and
        next            # skip to next input line.
}
$1 == "gud" {           # If this is a gud= line in 1 of the 1st 2 files...
        # If we are processing a line from the 1st file, set r1[] for the
        # current user name to the value found on this line from the 1st input
        # file; otherwise set r2[] for the current user name to the value found
        # on this line from the 2nd input file.
        f == 1 ? r1[u] = $2 : r2[u] = $2
}
f == 3 {                # If this line is from the 3rd input file...
        # If the user on this line was not in either of the 1st 2 files, save
        # the name in no_results.out.
        if(!($1 in r1) && !($1 in r2)) print > "no_results.out"
        # otherwise,
        # if the user on this line was not in one of the 1st 2 files or if the
        # value associated with this user was an empty string in one of the
        # files, save the name in no_gud.out.
        else    if(!($1 in r1) || r1[$1] == "" ||
                   !($1 in r2) || r2[$1] == "") print > "no_gud.out"
        # otherwise,
        # if the value for the user is different in the 1st 2 files, save the
        # name in no_matches.out.
        else    if(r1[$1] != r2[$1]) print > "no_matches.out"
        # otherwise,
        # the user is in both files and the values match; save the name in
        # matches.out.
        else    print > "matches.out"
}' File2 File3 File1    # The input files are File2, File3, and File1