Shell Programming and Scripting

It is extremely bad practice to pass miscellaneous text where printf requires a format string. In awk, worst case is a runtime error. With C, it's a massive security hole. For more info, read Uncontrolled format string - Wikipedia, the free encyclopedia

For your sake, and for the sake of those who may read your posts and emulate your code, adopt a safe, reliable approach. Instead of printf $i OFS, use printf '%s', $i OFS.

Regards,
Alister

Like this?

Code:

cols="3,5"
awk -F'\t' -v cols="$cols" 'BEGIN{n=split(cols,t,",")}{
for(i=1;i<=n;i++) $t[i]="";gsub(FS"+",FS);gsub("^"FS"+|"FS"+$","")}1' OFS='\t' file

Not very pretty and robust (esp. with a different FS), I know. May be someone will come up with a better/wittier solution. I hope you know to get the values in the variable cols from the user.

That's worse than "not very pretty and robust." It cannot distinguish between empty fields in the data and fields that have been nulled during the "cutting" process. If the output should contain field x and x is null from the beginning, instead of the output containing a null field it will be missing the field.


The following is a better approach:

Code:

# Usage: awk -v cols=f1,f2,... -f scriptpath input-file

BEGIN {
        split(cols, a, /,/)
        for (i in a)
                cut[a[i]]
}

{
        p=0
        for (i=1; i<=NF; i++) {
                if (i in cut)
                        continue
                printf "%s%s", (p ? OFS : ""), $i
                p=1
        }
        print ""
}

Further logic could be added to the BEGIN clause, or the invoking shell script, to comprehend field ranges (1-3,7-9), but this code needs each column listed explictly and individually in a comma-delimited string (1,2,3,7,8,9). Repetition and empty fields in the cols string are not a problem.

Regards,
Alister

OK..OK..I missed that.
Thanks for pointing out..

Hi Pamu, Elixir_sinari,and Alister,
Thanks for your reply. Actually I was trying to set it as array like

Code:

echo "Enter col numbers with space"
        read x
        echo 'You entered this line: ' $x
        set -A rarray $x
        for i in ....

something like this..
But I am stilling struggling to define it such a way. Actually if I want to make it user defined then they should also choose how many col the want to delete. May be sometime 2 or 3 etc. Thus I wanted to read the input as array.

Any suggestion?
Thanks again,
Mitra.