Title of the job
FNMV
Important Comment: The number of lines in the input file, and the
   *exact* typography for text input needs to be *rigorously* followed !!!!!!!!!
Temperatures (Next two lines: "List", or "Interval", then no of temps.)
   List
   1
Values (If "Interval", give start and finish temp.)
TEMPV
Pressure (in atm or bar - if given in atm, enter as a negative number. -1 is the G09 default)
PRV
Calculated properties of the species (e.g. from Gaussian output)
Electronic Energy
ELENV
Nature of species (Atom = 0, Linear = 1, or General = 3)
  3
Rotational factor (symmetry factor)
ROTFACTV
Electronic degeneracy (multiplicity)
MULTIV
Molecular Weight (amu)
MOLWEIV
Moments of Inertia (in amu x au2; none for Atom, 1 for Linear, 3 for General)
MOMINV
Vibrational Frequencies (first line: number; then freqs. in cm-1)
VIBFREQV

awk '
                                                # parse form file, fill in values found in data file
                                                # do this first so we don''t overwrite values by accident should a pattern fit
/FNMV/                  {print FNMV; next} 
/TEMPV/                 {print TEMPV; next}
/PRV/                   {print PRV; next}  
/ELENV/                 {print ELENV; next}   
/ROTFACTV/              {print ROTFACTV; next}
/MULTIV/                {print MULTIV; next} 
/MOLWEIV/               {print MOLWEIV; next}
/MOMINV/                {for (i=1; i<=3; i++)  print MOMINV[i]; next}
/VIBFREQV/              {print 3 * FC
                         for (i=3; i<=5; i++) for (j=1; j<=FC; j++) print FR[j,i]
                         next}

FNR != NR               {print; next}

                                                # parse data file, save relevant fields
NR==1                   {FNMV=FILENAME
                         gsub (/^.*\/|\..*$/, "", FNMV)
                        }
/SCF Done:/             {ELENV = $5}
/Molecular mass/        {MOLWEIV = $(NF-1)}
/ Temp.*Kelvin/         {TEMPV = $2}
/Kelvin.*Pressure/      {PRV = ($NF=="Atm."?"-":"") $(NF-1)}
/Multiplicity/          {MULTIV = $NF "."}
/Rotational.*ber/       {ROTFACTV = $NF}
/Frequencies --/        {FC++;for (i=3; i<=5; i++) FR[FC,i]=$i}   
/Eigenvalues -- /       {gsub (/\.[0-9][0-9][0-9][0-9][0-9]/,"& ")
                         for (i=1; i<=3; i++) MOMINV[i] = $(i+2)
                        }

' /tmp/feco4_s.log.txt templform

Title of the job
feco4_s
Important Comment: The number of lines in the input file, and the
   *exact* typography for text input needs to be *rigorously* followed !!!!!!!!!
Temperatures (Next two lines: "List", or "Interval", then no of temps.)
   List
   1
Values (If "Interval", give start and finish temp.)
298.150
Pressure (in atm or bar - if given in atm, enter as a negative number. -1 is the G09 default)
-1.00000
Calculated properties of the species (e.g. from Gaussian output)
Electronic Energy
-1715.82310939
Nature of species (Atom = 0, Linear = 1, or General = 3)
  3
Rotational factor (symmetry factor)
2.
Electronic degeneracy (multiplicity)
1.
Molecular Weight (amu)
167.91460
Moments of Inertia (in amu x au2; none for Atom, 1 for Linear, 3 for General)
1284.73849
1536.05333
2170.19761
Vibrational Frequencies (first line: number; then freqs. in cm-1)
21
45.7886
96.4952
353.2741
427.8395
499.7992
640.4272
2062.0748
66.7894
96.9991
363.5129
430.9072
537.9941
640.7995
2062.6585
79.7836
335.4020
422.7705
448.4787
595.3209
2042.2981
2151.4066