UNIX for Dummies Questions & Answers

Hi,

I am trying to exclude certain rows in File 1, based on File 2. i.e. in the example below, File 3 should be the output; i.e. the rows in File 2 are excluded from File 1. Any hints/suggestions would be highly appreciated.

Input File 1:

Code:

a	1	xxx
b	1	wje
c	5	ere
c	2	qqq
d	3	yyy

Input File 2:

Code:

b	1
c	5

Output File 3:

Code:

a	1	xxx
c	2	qqq
d	3	yyy

thanks!

Code:

awk 'FNR==NR {a[$1$2]++; next} {if (! a[$1$2])print}' file2 file1 > file3

Thanks Aia!

It would be great if you could elaborate a bit on the structure and syntax of the code!

FNR==NR : FNR and NR are built-in management variables in awk. FNR keeps a tally of the records read from the current file, NR keeps a tally of every record so far read from any files given.
If FNR is equal to NR, then we are dealing with the first file, in this case file2 and it execute the following part:
{a[$1$2]++; next} : That creates an array named a, which index is the combination of fields 1 and 2 and then skip to next line. This will happen only with first file given as argument

{if (! a[$1$2])print} : When the program gets here, it is dealing with the second file, and if it has not seen fields 1 and 2 before, it displays it.

Note:

It is best to use a subscript separator and not just glue the index fields together to avoid possible index creep:

For example, suppose that you have the fields A1 and 1 and also the the fields A and 11. They would both produce the index "A11", which would corrupt the results.

With the standard awk SUBSEP subscript separator , (character 034 by default) this can be avoided:

Code:

awk 'NR==FNR{A[$1,$2]; next} !(($1,$2) in A)' file2 file1

So, to get things straight:

Code:

NR==FNR{A[$1,$2]; next}

- this reads file 2 and creates an array for each row in file 2

Code:

!(($1,$2) in A)

- after file 2 has been read, file 1 is read and output is printed only if the fields are not in the array A.

Is this correct? Does file 2 get read before file 1?

thanks! This has been very instructive.

You are welcome... Correct, and yes file 2 gets read before file 1.