UNIX for Dummies Questions & Answers

my file or content of the file looks like this:

Code:

HR-BUSPARTNET
SC-POINQUIRY
BATCH
FIN-CHOPDATARESTRICT
HR-DATABASEACCESSNOEXEC
GL-EXTINQ
RSS
SC-APPROVER
ESS

all said and done, i'd like to have it look like this:

Code:

HR-BUSPARTNET,SC-POINQUIRY,BATCH,FIN-CHOPDATARESTRICT,HR-DATABASEACCESSNOEXEC,GL-EXTINQ,RSS,SC-APPROVER,ESS

---------- Post updated at 09:47 PM ---------- Previous update was at 09:37 PM ----------

never mind, awk -v ORS="," '1' inputfile, solved.

Consider piping to following sed command to replace the obligatory trailing comma with a newline character:
| sed "s/,$/\n/"

A non-awk approach for the posterity: $ tr '\n' ',' <input | sed "s/,$/\n/" >output

To: lawsongeek
The file produced by:

Code:

awk -v ORS="," '1' inputfile

not only includes an unwanted trailing comma, it is also missing a trailing <newline> character. Therefore, by definition, the output is not a text file. This might or might not be important depending on what you are going to do with the output from this command.

To: junior-helper
The code:

Code:

tr '\n' ',' <input | sed "s/,$/\n/" >output

might work on some systems, but it is not portable. The output of the tr command will not have a trailing <newline> character (so by definition, the output is not a text file). And, according to the standards, the behavior of sed is unspecified if any of its input files is not a text file.

A couple of ways to portably merge a file containing one or more lines into a single line text file are:

Code:

awk '
FNR==2 { d = "," }
{ printf("%s%s", d, $0)}
END { print ""}' input > output

and:

Code:

(tr '\n' ',' <input; echo) | sed "s/,$//" >output

Note, however, that if the size of the input file is larger than the LINE_MAX limit on your system (which can be as small as 2048 bytes), the resulting output file still will not be a text file (and in the 2nd pipeline, the behavior of sed is still unspecified if the size of the input file is LINE_MAX or larger).

Hello lawsongeek,

One more approach not effective as Don's but may help.
Thanks Don for nice approach.

Code:

awk '{for(i=1;i<=NR;i++){a=a ORS $0;next}} END{gsub(/^[[:space:]]/,Y,a);gsub(/[[:space:]]/,",",a); print a}' filename

Output will be as follows.

Code:

HR-BUSPARTNET,SC-POINQUIRY,BATCH,FIN-CHOPDATARESTRICT,HR-DATABASEACCESSNOEXEC,GL-EXTINQ,RSS,SC-APPROVER,ESS

Thanks,
R. Singh

This is a variant of the efficient one that prints the last newline only if the inputfile is not empty.

Code:

awk '
{ printf ("%s%s", d, $0); d="," }
END { if (NR>0) print ""}' input > output

Hi RavinderSingh,
If you want to take this approach, wouldn't this be more efficient:

Code:

awk '{a=(a==""?"":a",")$0;next}} END{print a}' filename

I don't see the need for the for loop; did I miss something?

The reason I didn't use this approach is that the script I suggested before will produce the desired output successfully even if the total length of the output is longer than LINE_MAX bytes as long as no single input line is longer than LINE_MAX. The behavior with this script is again unspecified if the length of the string stored in a is (LINE_MAX -1) or more bytes (which will happen whenever the size of the input file is LINE_MAX or more bytes).
----------------------------------------------
Update: Removed extraneous } as suggested by RavinderSingh13 in next message.

Posted by Don:

Thank you Don for really nice solution, but seems there is an extra } character, so removed the same now.

Code:

awk '{a=(a==""?"":a",")$0;next} END{print a}' filename

Thanks,
R. Singh