UNIX for Dummies Questions & Answers

$cat file
ID      a       b       c       d
day     10      5       100     50
cat     20      6       200     50
dog     NA      8       NA      50
car     15      NA      NA      NA

$cat output
ID      a       b       c       d
day     10      5       100     50
cat     20      6       200     50
dog     15      8       150     50
car     15      6.33    150     50

awk '
        BEGIN {
                CONVFMT = "%.2f"
        }
        NR == 1 {
                print $0
        }
        NR > 1 {
                for ( i = 1; i <= NF; i++ )
                {
                        A[NR,i] = $i
                        if ( $i != "NA" && i != 1 )
                        {
                                T[i] += $i
                                C[i]++
                        }
                }
        }
        END {
                j = 2
                while ( j <= NR )
                {
                        for ( i = 1; i <= NF; i++ )
                        {
                                if ( i == 1 )
                                        s = A[j,i]
                                else
                                        s = s ? s OFS ( A[j,i] == "NA" ? T[i] / C[i] : A[j,i] ) : A[j,i]
                        }
                        print s
                        ++j
                }
        }
' OFS='\t' file

awk '
  NR==FNR {
    if(NR>1) for(i=2; i<=NF; i++) if( $i!="NA" ) {
      S[i]+=$i
      N[i]++
    }
    next 
  } 
  {
    if(NR>1) for(i=2; i<=NF; i++) if( $i=="NA" ) $i=S[i]/N[i]
  }
  1
' OFS='\t' CONVFMT="%.2f" file file