UNIX for Dummies Questions & Answers

Hi,
i'd like to know if the following is possible with a shell script, and can't find the answer in the search.

Suppose i have a logfile build like this:
[15/Jul/2005:10:47:22 0100][3-I] # 8 :riuyzp1028
[15/Jul/2005:10:47:24 0100][3-I] # 38 : riuyzp1028
[15/Jul/2005:10:47:30 0100][3-I] # 25 : riuyvzp1032
[15/Jul/2005:10:47:34 0100][3-I] # 30 : nlkljpa0202
[15/Jul/2005:10:47:34 0100][3-I] # 1 : nlklja0205
[15/Jul/2005:10:47:35 0100][3-I] # 38 : riuyzp1028
[15/Jul/2005:10:47:35 0100][3-I] # 25 : riuyvzp1032
[15/Jul/2005:10:47:37 0100][3-I] # 30 : dsjfhh23
[15/Jul/2005:10:47:38 0100][3-I] # 1 : sdfjkh45

I want a script to count the number of occurences of each unique machine (where "riuyzp1028" is the machine name).
The output i'd like to see is, the machine names followed by the number of occurences...like this:
riuyzp1028 3
riuyvzp1032 2
nlkljpa0202 1
nlklja0205 1
dsjfhh23 1
sdfjkh45 1

I wan't to use this script to be able to check which machine is generating the most entries in my logfile.

Thanks for your help in advance !

awk ' { print $6 }' file.txt |sort |uniq -c

to reverse string and the number of occurence
awk ' { print $6 }' file.txt |sort |uniq -c |awk ' {print $2 " " $1 } '

nawk -f free.awk file.txt | sort -n -k 2,2

free.awk:

Code:

BEGIN {
  FS=":"
}

function trim(str)
{
      sub("^[ ]*", "", str);
      sub("[ ]*$", "", str);
      return str;
}

{
  arr[trim($NF)]++
}
END {
  for ( i in arr )
    printf("%s %s\n", i, arr[i])
}

or better yet:

nawk -f free.awk file.txt

free.awk:

Code:

BEGIN {
  FS=":"
}

function trim(str)
{
      sub("^[ ]*", "", str);
      sub("[ ]*$", "", str);
      return str;
}

{
    f=trim($NF)
    f in count || arr[++tally] = f
    count[f]++
}
END {
  for ( i=1; i <= tally; i++ )
    printf("%s %s\n", arr[i], count[arr[i]])
}

Wow you guys are fast.
Thanks a lot !