Replace a field in a comma separated file


 
Thread Tools Search this Thread
Top Forums UNIX for Beginners Questions & Answers Replace a field in a comma separated file
# 1  
Old 03-05-2020
Replace a field in a comma separated file

Hello Experts,

I have a sample comma separated file as having date data in field # 5 and field #8. Field # 4 and 7 (fields before the date field) are indicators:

This is just a sample data, the actual file may have n number of date fields.

Code:
29,A Store,A Street,1,111213,aaaa,0,891213
30,B Store,B Street,0,991213,aaaa,1,61213
31,C Store,C Street,1,51213,aaaaa,1,81213
32,D Store,D Street,0,0,aaaa,1,150323
33,E Store,E Street,1,121212,bbbb,0,0
34,F Store,F Street,1,101212,cccc,0,971212


I need to update field #5 (depending on the value in field # 4 (indicator field)) and field #8 (depending on the value in field#7) and so on as :

1. If field # 4 = 0 and field # 5 <> 0 (say data is : 991213), then append '19' to the string in field # 5 and make the final value
as : 1999-12-13. This is for years before 2000

2. If field # 4 = 0 and field # 5 = 0 (say data is : 0), then the final value as : 0001-01-01

3. If field # 4 = 1, then
a. check if field # 5 has length = 5, then (for data say: 51213), append '200' so that the final value should be 2011-12-13
b. Else, (for data say : 111213), append '20' so that the final value appears as : 2011-12-13.

Input parameters to the script :
$1 : file name
$2 , $3, ........ this depends on the number of date fields which need to be transformed.

I have written the following code:

Code:
#! /usr/bin/ksh

# Read File name
INPUT=$1

 while IFS=',' read -r f1 f2 f3 f4 f5 f6 f7 f8
 do 
 For Century = 0
  if [ $f4 -eq 0 -a $f5 -ne 0 ]
  then
      echo "19$f5" | sed 's/./&-/4;s/./&-/7' ;
  fi

 For 0 in date
  if [ $f4 -eq 0 -a $f5 -ne 0 ]
  then
      echo "00010101" | sed 's/./&-/4;s/./&-/7' ;
  fi

 for century = 1
  if [ $f4 -eq 1 ]
  then
      char_len=`expr length $f5`
      if [ $char_len -eq 5 ]
      then
         echo "200$f5" | sed 's/./&-/4;s/./&-/7';
      else
          echo "20$f5" | sed 's/./&-/4;s/./&-/7';
      fi
  fi

 done < "$INPUT"

I am able to transform the data for Field # 5 only.
Could you please suggest a better approach for this requirement such that I am able to transform the data for field # 8 as well.


Thank you
# 2  
Old 03-05-2020
a bit verbose and can be simplified - just following your description.

Code:
 awk -v fld='5,8' -f hsquared.awk myFile.csv

where hsquared.awk is:
Code:
BEGIN {
  FS=OFS=","
  fld=(!fld)?"5":fld
  fldN=split(fld, fldA,FS)
}
function convF(str ) {
 return (substr(str,1,4) "-" substr(str,5,2) "-" substr(str,7))
}
{
   for(i=1;i<=fldN;i++) {
     if ($(fldA[i]-1)==0 && $(fldA[i])!=0)
       $(fldA[i])=convF("19" $(fldA[i]))

     if ($(fldA[i]-1)==0 && $(fldA[i])==0)
       $(fldA[i])=convF("00010101")

     if ($(fldA[i]-1)==1) {
        if (length($(fldA[i])) == 5)
           $(fldA[i])=convF("200" $(fldA[i]))
        else
           $(fldA[i])=convF("20" $(fldA[i]))
     }

   }
}
1

results in:
Code:
29,A Store,A Street,1,2011-12-13,aaaa,0,1989-12-13
30,B Store,B Street,0,1999-12-13,aaaa,1,2006-12-13
31,C Store,C Street,1,2005-12-13,aaaaa,1,2008-12-13
32,D Store,D Street,0,0001-01-01,aaaa,1,2015-03-23
33,E Store,E Street,1,2012-12-12,bbbb,0,0001-01-01
34,F Store,F Street,1,2010-12-12,cccc,0,1997-12-12

awk -f hsquared.awk myFile.csv will do only field 5 by default
This User Gave Thanks to vgersh99 For This Post:
# 3  
Old 03-05-2020
Thanks for the quick response.

I would mention that the number of arguments calling the script could be more than 2 and the number of fields to be transformed can be more than 2.

The field # 12 (though not present in my sample file) would be a new date field that would be transformed.

Could you please share your thoughts on this.

Please let me know if you need more inputs from my end.

Quote:
Originally Posted by vgersh99
a bit verbose and can be simplified - just following your description.

Code:
 awk -v fld='5,8' -f hsquared.awk myFile.csv

where hsquared.awk is:
Code:
BEGIN {
  FS=OFS=","
  fld=(!fld)?"5":fld
  fldN=split(fld, fldA,FS)
}
function convF(str ) {
 return (substr(str,1,4) "-" substr(str,5,2) "-" substr(str,7))
}
{
   for(i=1;i<=fldN;i++) {
     if ($(fldA[i]-1)==0 && $(fldA[i])!=0)
       $(fldA[i])=convF("19" $(fldA[i]))

     if ($(fldA[i]-1)==0 && $(fldA[i])==0)
       $(fldA[i])=convF("00010101")

     if ($(fldA[i]-1)==1) {
        if (length($(fldA[i])) == 5)
           $(fldA[i])=convF("200" $(fldA[i]))
        else
           $(fldA[i])=convF("20" $(fldA[i]))
     }

   }
}
1

results in:
Code:
29,A Store,A Street,1,2011-12-13,aaaa,0,1989-12-13
30,B Store,B Street,0,1999-12-13,aaaa,1,2006-12-13
31,C Store,C Street,1,2005-12-13,aaaaa,1,2008-12-13
32,D Store,D Street,0,0001-01-01,aaaa,1,2015-03-23
33,E Store,E Street,1,2012-12-12,bbbb,0,0001-01-01
34,F Store,F Street,1,2010-12-12,cccc,0,1997-12-12

awk -f hsquared.awk myFile.csv will do only field 5 by default
# 4  
Old 03-05-2020
I'll leave it up to you to implement the shell wrapper script, but...
for the 3 fields (5,8 and 12) to be modified, awk should be called as:
Code:
awk -v fld='5,8,12' -f hsquared.awk myFile.csv


Last edited by vgersh99; 03-05-2020 at 01:26 PM..
This User Gave Thanks to vgersh99 For This Post:
# 5  
Old 03-05-2020
Thanks.
I shall try and update.

Quote:
Originally Posted by vgersh99
it's up to you to implement the shell wrapper script, but...
for the 3 fields (5,8 and 12) to be modified, awk should be called as:
Code:
awk -v fld='5,8,12' -f hsquared.awk myFile.csv

# 6  
Old 03-05-2020
How about
Code:
awk -F, -v"FLDS=5,8" '
BEGIN                   {FCNT = split(FLDS, FLD)
                        }

function CV(TMP)        {Y = int(TMP/1E4)
                         return sprintf ("%d-%02d-%02d", Y, int(TMP%Y/100), TMP%100)
                        }

                        {for (i=1; i<=FCNT; i++)        {IX = FLD[i]
                                                         if ($IX) $IX = CV((19+$(IX-1))*1E6 + $(IX))
                                                             else $IX = "0001-01-01"  
                                                        }
                        }
1
' OFS=, file
29,A Store,A Street,1,2011-12-13,aaaa,0,1989-12-13
30,B Store,B Street,0,1999-12-13,aaaa,1,2006-12-13
31,C Store,C Street,1,2005-12-13,aaaaa,1,2008-12-13
32,D Store,D Street,0,0001-01-01,aaaa,1,2015-03-23
33,E Store,E Street,1,2012-12-12,bbbb,0,0001-01-01
34,F Store,F Street,1,2010-12-12,cccc,0,1997-12-12

This User Gave Thanks to RudiC For This Post:
# 7  
Old 03-05-2020
Thanks.

I am writing a wrapper script to call the awk (say driver.awk) script

Code:
# Skip the 1st argument as it is the file name
shift
# fetch the argument values, in comma separated form
arg_list=`echo $* | tr ' ' ','`

awk -v fld='$arg_list' -f driver.awk file.txt > file.tmp

However, I get the following error:

awk: The field -1 cannot be less than 0.

Now, if i hard code the fields to be transformed, then it works fine.

Code:
awk -v fld='8,12' -f driver.awk file.txt > file.tmp

Could you please suggest a way to dynamically set the fields to be transformed for the AWK command.

Thanks.
Login or Register to Ask a Question

Previous Thread | Next Thread

10 More Discussions You Might Find Interesting

1. Shell Programming and Scripting

awk to parse comma separated field and removing comma in between number and double quotes

Hi Experts, Please support I have below data in file in comma seperated, but 4th column is containing comma in between numbers, bcz of which when i tried to parse the file the column 6th value(5049641141) is being removed from the file and value(222.82) in column 5 becoming value of column6. ... (3 Replies)
Discussion started by: as7951
3 Replies

2. Shell Programming and Scripting

Comma separated to rows based on field

Hi to all, I have a file like: chr1 a1 a2 a3 a4 a5 a6,a7,a8,a9 chr1 b1 b2 b3 b4 b5 b6,b7 chr2 c1 c2 c3 c4 c5 c6,c7,c8,c9,c10 ... I would like an output like this: chr1 a6 chr1 a7 chr1 a8 chr1 a9 chr1 b6 chr1 b7 chr2 c6 chr2 c7 chr2 c8 (6 Replies)
Discussion started by: aec
6 Replies

3. UNIX for Dummies Questions & Answers

[solved] Comma separated values to space separated

Hi, I have a large number of files which are written as csv (comma-separated values). Does anyone know of simple sed/awk command do achieve this? Thanks! ---------- Post updated at 10:59 AM ---------- Previous update was at 10:54 AM ---------- Guess I asked this too soon. Found the... (0 Replies)
Discussion started by: lost.identity
0 Replies

4. Shell Programming and Scripting

How to split the comma separated file?

Hi, I have a filein unix like ABC,CDE BCD,KHL and the output i need is like column1 column2 ABC,CDE ABC ABC,CDE CDE BCD,KHL BCD BCD,KHL KHL. Can some body help me out? Hi, The code is working fine. But in my file each row does not have always 1 comma. It may... (6 Replies)
Discussion started by: jagdishrout
6 Replies

5. Shell Programming and Scripting

Need Help - comma inside double quote in comma separated csv,

Hello there, I have a comma separated csv , and all the text field is wrapped by double quote. Issue is some text field contain comma as well inside double quote. so it is difficult to process. Input in the csv file is , 1,234,"abc,12,gh","GH234TY",34 I need output like below,... (8 Replies)
Discussion started by: Uttam Maji
8 Replies

6. Shell Programming and Scripting

Comma separated file

Hi all, I have the following files types: FileA: 100, 23, 33, FileB: 22, 45, 78, and i want to make File C: 100,22 23,45 33,78 any nice suggestions for making it easy. (3 Replies)
Discussion started by: hen1610
3 Replies

7. Shell Programming and Scripting

Inserting string in between field in comma separated file

Hello Mates, I have one txt file having commo seperated values. I have to insert string "FALSE" in 2nd field from the end. E.G SE18 6RN,,,,5439070,1786840,,1000002148671600,123434 Out put should be: SE18 6RN,,,,5439070,1786840,FALSE,1000002148671600,123434 Can some one help me to... (8 Replies)
Discussion started by: krsnadasa
8 Replies

8. Shell Programming and Scripting

How to format file into comma separated field

Guys, Need you help, i have a a file content that look like this. Nokia 3330 <spaces><spaces><more spaces>+76451883874 Nokia 3610 +87467361615 so on and so forth, - there are so many spaces in between. - e.g.... (5 Replies)
Discussion started by: shtobias
5 Replies

9. Shell Programming and Scripting

Replace comma by space for specified field in record

Hi, i want to replace comma by space for specified field in record, i mean i want to replace the commas in the 4th field by space. and rest all is same throught the record. the record is 16458,99,001,"RIMOUSKI, QC",418,"N",7,EST,EDT,902 16458,99,002,"CHANDLER,... (5 Replies)
Discussion started by: raghavendra.cse
5 Replies

10. Shell Programming and Scripting

Its PERL + Comma separated seventh field

Hi Friends, I'm working on a perl script, which seems to be simpler. But I'm very new to PERL scripting. I have a comma separated data file, from which I need to extract only the seventh field data out of available twenty fields to an array using perl. Any help would be much appreciated. ... (17 Replies)
Discussion started by: ganapati
17 Replies
Login or Register to Ask a Question