UNIX for Dummies Questions & Answers

<?xml version="1.0" encoding="UTF-8" ?>
<archives>
  <archive id="ffghgsddes">
    <file line="1">
      <author>953b</author>
      <time>18:03</time>
      <text>this is an evidence regarding ...</text>
    </file>
    <file line="2">
      <author>04bfa</author>
      <time>18:03</time>
      <text>we have seen those documents before </text>
    </file>
     . 
     . 
     .
 </archive>
 <archive>
 .
 .
 .
 </archive>
</archives>

$ sed 's/<[^>]*>//g' xml |  tr -d '\n' ; echo
            953b      18:03      this is an evidence regarding ...              04bfa      18:03      we have seen those documents before          .      .      .   . . .

$

$ cat xmlg.awk

BEGIN { RS="<";         FS=">"; ORS="\r\n"  }

# Skip weird XML specification lines or blank records
/^\?/ || /^$/   {       next    }

# Handle close tags
/^[/]/  {
        N=D;    while((N>0) && ("/"STACK[N] != $1))     N--;

        if("/"STACK[N] == $1)   D=(N-1);
        POP++;

        if(POP == 2)
        {
                if(!HEADER++)
                {
                        split(ARG[1], Z, SUBSEP);
                        printf("%s %s", Z[2], Z[3]);
                        for(N=2; N<=ARG_; N++)
                        {
                                split(ARG[N], Z, SUBSEP);
                                printf("|%s %s", Z[2], Z[3]);
                        }

                        printf("\n");
                }

                printf("%s", DATA[ARG[1]]);
                for(N=2; N<=ARG_; N++)
                        printf("|%s", DATA[ARG[N]]);
                printf("\n");
        }
        next
}

# Handle open tags
{
        gsub(/^[ \r\n\t]*/, "", $2);    # Whitespace isn't data
        gsub(/[ \r\n\t]*$/, "", $2);

        # Reset parameters
        POP=0;

        M=split($1, A, " ");
        STACK[++D]=A[1];

        # Handle parameters
        Q=split(A[2], B, " ");
        for(N=1; N<=Q; N++)
        {
                split(B[N], C, "=");
                gsub(/['"]/,"", C[2]);
#               PARAM[C[1]]=C[2];
#               print C[1], "=", PARAM[C[1]];

                I=D SUBSEP STACK[D] SUBSEP C[1];
                if(!SEEN[I]++)
                        ARG[++ARG_]=I;

                DATA[I]=C[2];
        }

        if($2)
        {
                I=D SUBSEP STACK[D] SUBSEP "CDATA";
                if(!SEEN[I]++)
                        ARG[++ARG_]=I;

                DATA[I]=$2;
        }
}

$ awk -f xmlg.awk file.xml

archive id|file line|author CDATA|time CDATA|text CDATA
ffghgsddes|1|953b|18:03|this is an evidence regarding ...
ffghgsddes|2|04bfa|18:03|we have seen those documents before
jhljkhlasdf|1|953b|18:03|this is an evidence regarding ...
jhljkhlasdf|2|04bfa|18:03|we have seen those documents before

$ awk -f xmlg.awk file.xml > output.txt