Shell Programming and Scripting

Hello Freinds,

I am facing a starange problem with gawk .

My programme is as follows

#!/bin/sh

gawk -v AMPLITUDE=$1 -v freq=$2 ' \
BEGIN{
for(i=0; i<=2559; i++){
validec = sprintf("%1.3f", AMPLITUDE * sin( (i/2559) * 2* freq * 3.14159 ) )
validec = floor(validec);
print "=> "validec
itxdata = toHEXA(validec,3)
}
}
#================
#Function For flooring
#================
function floor(x,r)
{
r = int(x) ;
print "x=>" x
print "r=>" r
if (r > x)
r--;
return ( r + 0 );
}
'
I m running the script by giving a two arguments like
./<scriptname> 2000 10

My problem is when the floor function is going for a negative number
such as when it passes -2.450 it returns me -2 instead of -3. But in nawk it is ok.

And when I am using the floor function in a separate programe alone

as below it gives me the correct answer ie, -3

#!/bin/sh
gawk ' \
BEGIN{
val = floor(-2.45);
print "AFTER Flooring " val
}
function floor(x,r)
{
r = int(x) ;
print "x=>" x
print "r=>" r
if (r > x)
r--;
return ( r + 0 );
}
'

Actually in the first programe gawk the statement if(-2 > -2.45) why goes false I ve no idea.

I m curious to know what is the problem with gawk Please help..
Thanks in Adavance
user_prady

In the first example you are passing 'x' as a string, in the second as a number.
So that's why the 'if' does not behave as you expect.

Thnaks for your kind reply ..

Oh is it the problem !!!

So if that the problem I ll multiply the string with one(1) then I ll pass it and it should give me my expected result.

But I tried that one it won't work , Is there any other way that I can send it as number not as a string..

user_prady

This may or may not be an issue but ...

Your floor function is expecting two parameters i.e. floor(x,r).
You are passing in only one parameter i.e. x.

The second parameter is defined to be used as a local variable.

Jean-Pierre.

Passing a number a number works as expected:

Code:

$ gawk ' \
> BEGIN{
> val = floor(-2.45);
> print "AFTER Flooring " val
> }
> function floor(x,r)
> {
> r = int(x) ;
> print "x=>" x
> print "r=>" r
> if (r > x)
> r--;
> return ( r + 0 );
> }
> '
x=>-2.45
r=>-2
AFTER Flooring -3

Passing a string does not work:

Code:

$ gawk ' \
> BEGIN{
> val = floor("-2.45");
> print "AFTER Flooring " val
> }
> function floor(x,r)
> {
> r = int(x) ;
> print "x=>" x
> print "r=>" r
> if (r > x)
> r--;
> return ( r + 0 );
> }
> '
x=>-2.45
r=>-2
AFTER Flooring -2

Adding a zero to the parameter will convert it from a string to a number:

Code:

$ gawk ' \
> BEGIN{
> val = floor("-2.45" + 0);
> print "AFTER Flooring " val
> }
> function floor(x,r)
> {
> r = int(x) ;
> print "x=>" x
> print "r=>" r
> if (r > x)
> r--;
> return ( r + 0 );
> }
> '
x=>-2.45
r=>-2
AFTER Flooring -3

Yes that's the answer . I am now getting the exact answer..
Thank You all again...