Shell Programming and Scripting

#!/usr/bin/awk -f
# Awk File : cbl_args.awk

function print_args_count() {# Function for printing filename and arguments count 
   if (file)                 # Only if file name is set.
      print file," #Args=" args_count;
}

FNR==1  {              # New input file
   print_args_count();       # Print argument count for previus file
   file         = FILENAME;  # Memorize the file name
   proceed_args = 0;         # Reset flag 'USING' keyword found, args coming..
   args_count   = 0;         # Reset arguments count
}

{                            # For all input lines
   sub(/\*.*$/, "");         # Removes comments (all chars from first * to end of line)
}

/PROCEDURE DIVISION/,/\./ {  # For lines from 'PROCEDURE DIVISION' to '.'
   count = NF;               # Argument count in line set to fields count
   if (/PROCEDURE DIVISION/) # If 'PROC. DIV.' 
      count -= 2;            #   PROC. and DIV. aren't arguments
   if (/USING/) {            # If 'USING'
      proceed_args=1;        #   set flag 'USING', args coming..
      --count;               #   'USING' is'nt an argument
   }                         #
   if (NF == ".")            # If final point alone (not 
      --count;               #   '.' isn't an argument
   if (proceed_args)         # If flag arguments coming set
       args_count += count;  #   add new arguments found in the line
}

END {                        # All input files have been read
   print_args_count();       # Print argument count for last file
}

   if ($NF == ".")            # If final point alone