Shell Programming and Scripting

Hi LMHmedchem,
Well done. I see no reason why the code you have will not meet your requirements.

You might want to consider this alternative that should be slightly faster (since it doesn't split or sort the input, and only looks at each field once):

Code:

#!/bin/sh

# assumes that the input file has a header row
# assumes that the first column is the index and the second column is a name
# assumes that all columns after the first two contain data

# input file name (defaults to "file"
input_file=${1:-file}
# output file name (defaults to "output"
output_file=${2:-output}

awk '
BEGIN {	FS = OFS = "\t"
}
NR > 1 {m = $3
	for(i = 4; i <= NF; i++)
		if($i && ($i < m || !m))
			m = $i
	if(m)	print $1, $2, m
}' "$input_file" > "$output_file"

Note that even if you don't want default filenames to be supplied if you invoke your script with less than two operands, you should still quote the filenames in the last line of your script in case someone invokes your script with a quoted operand containing an IFS character.

Thank you for the solution. I have not seen that syntax to supply a default argument. I have always just tested the value of the argument and set a value if there isn't one. Your suggestion is much preferable because it's not always easy to tell which argument is missing.

If I understand, you set the IO delimiters, and then start with the second row NR > 1. You assign the value of the third element to m, m = $3, and then compare each other element to m starting with element 4 up to the number of fields, for(i=4; i<=NF; i++).

The comparison, if($i && ($i < m || !m)), is a bit unclear to me. I would guess that if($1) is true if $i is not 0, like evaluating a boolean. The if(($i < m) keeps track of the lowest value but I don't know what the ||!m "or not m" does.

Also, is there any case where if(m) print $1, $2, m will not evaluate as true? I guess if $3=0 and all the rest of the elements are also 0 that statement will not be true. Is that how you trap against all 0 values in a row? If so, I would probably add an else there to print the id and name also with a user message to keep the output fully determined.

You haven't had to explicitly insert the tabs to the print statement since you specified the delimiter with OFS.

I have tried this with input where 0 is 0.0 and 0.0000 and it still works. How does that work with no explicit types?

Sorry for all the questions.

Thanks,

LMHmedchem

Note that if you want to use the default value for the 1st operand and specify a different (non-default) value for the 2nd operand, you still have to supply both operands. To specify a default input filename of "file" and a non-default output filename of "new-output", you can use either:

Code:

your_script_name file new-output

or:

Code:

your_script_name "" new-output

Yes.

The variable m holds the minimum found so far in columns 3 through NF on the current input line (or the zero from column 3 if all values seen so far are zero). The if($i && ...) prevents the current column from resetting m if $i is zero or an empty string. If that condition is met, the $i < m || !m is used to reset m if the current column value is less than any value found earlier on the line or if the current value is the first non-zero value we have seen on this line but is greater than zero.
I used that code because it produces no output if all columns on a line have zero (or empty string) values just like the code you used to print results:

Code:

             for(x in line_array) {
                if(line_array[x] != 0) { print id "\t" name "\t" line_array[x];  break; }
             }

If you want to print whatever was in field 3 if all values are zero, change:

Code:

	if(m)	print $1, $2, m

to:

Code:

	print $1, $2, m

If you want alternative text to be printed instead you can either use something like:

Code:

	if(m)	print $1, $2, m
	else	print $1, $2, "all-zero"

or more concisely:

Code:

	print $1, $2, m ? m : "all-zero"

Yes.
When both values being compared are numeric values, awk performs a numeric comparison and all zero values compare equal.
Never apologize for asking questions. That is why we're here and that is how you learn.