Shell Programming and Scripting

BEGIN {
 FS=OFS=","
 mon="January|February|March|April|May|June|July|August|September|October|November|December"
   monN=split(mon, monA, "|");
   for(i=1; i<=monN; i++) {
     monA[monA[i]]=i;
     delete monA[i];
   }

   if (!col) col="3"

   colN=split(col, colA, " ")
}

function conv(str,  strA)
{
   split(str, strA, " ")
   return(sprintf("%d-%02d-%02d", strA[3], monA[strA[1]], strA[2]))
}

FNR>1 {
   for(i=1; i<= colN; i++)
     $colA[i]=conv($colA[i])
}
1

grep -Eo "[A-Z][a-z]* [0-9]{1,2} [0-9]{4}" /tmp/sample.txt |
LC_ALL=C date -f- +"%B %-d %Y:%F" |
awk '
NR == FNR       {T[$1] = $2
                 next
                }
FNR > 1         {$3 = T[$3]
                 $5 = T[$5]
                }
1
' FS=: - FS=, OFS=, /tmp/sample.txt

awk '
  BEGIN {
    FS=OFS=","
    split("January,February,March,April,May,June,July,August,September,October,November,December", MNUM)
    for(i in MNUM)
      MON[MNUM[i]]=i                                                                         
  }                          
  {
    for(i=1; i<=NF; i++)
      if ($i ~ /^[[:alpha:]]+ [0-9]{1,2} [0-9]{4}$/) {
        split($i, D, " ")
        $i=sprintf("%d-%02d-%02d",D[3],MON[D[1]],D[2])
      }                                               
    print
  }      
' file