Shell Programming and Scripting

Originally Posted by Don Cragun

You can find lots of examples in the UNIX & Linux Forums of awk scripts that work on two or more input files and that produce two or more output files (although we don't need to do the latter in this case).

In an awk program, each group of statements is of the general form:

Code:

condition { action }

Before any lines are read from any of the input files named as operands, the commands specified in the actions of all groups with the condition BEGIN (if there are any) are executed in the order in which they appear in the awk program. There aren't any BEGIN sections in my code for this thread.

After all files of the input files named as operands have been processed, all commands specified in the actions of all groups with the condition END (if there are any) are executed in the order in which they appear in the awk program.

All other groups are processed in the order in which they appear in the awk program for every record (with default options, each input line in each file is a record) is processed. If the condition for a group evaluates to a non-zero numeric value or to a non-empty string string value (i.e., evaluates to TRUE), the statements in the action for that group are executed in order; otherwise the statements in that group are skipped for that input record. If there is no condition at the start of a group, the commands in the action in that group are always executed. If the condition evaluates to TRUE and the action and braces ({ and }) are omitted, a default action of print (which prints the current state of the current input record) is performed.

I will assume that you can read the manual page on for awk (by giving the command man awk at a ksh primary prompt in your shell window) to see what the standard awk variables, functions, and statements do. I would hope that the comments I supplied in each group explain what that group is trying to do.

The first group:

Code:

{	# Get rid of <carriage-return> at end of line if there
	# is one.  Set cr to <carriage-return> if there was one; otherwise
	# set it to an empty string.
	cr = sub(/\r$/, "") ? "\r" : ""
}

(with no condition is executed for every record read from both input files and does exactly what the comments say it does.

The second group:

Code:

FNR == NR {
	# For all lines in the first input file...
	# Set a search string as an index in the add_com[] array corresponding
	# to this input line.
	add_com["test \"analog/" $0 "\""]
	next
}

is executed when the condition FNR == NR evaluates to TRUE. It evaluates to TRUE when the Number of Records read from the current File (FNR) is equal to the Number of Records read from all files (NR) which happens when any line from the 1st input file is being processed. The next statement in this action causes all remaining statements in the current action (if there are any) and in any following groups to be skipped for this input record, causes the next available input record to be read, and starts processing groups in order for that new input record. The combination of the action and the next statement guarantee that the following group will not be performed for records read from the 1st input file.

The third group:

Code:

{	# For all lines in the second input file, look for a match in add_com[].
	for(i in add_com)
		if(index($0, i)) {
			# Match found.
			# Set this line in the output buffer to include a
			# comment and put back the <carriage-return> if there
			# was one.
			o[FNR] = $0 "  ! comment" cr
			# Note that a modification was made.
			mod = 1
			next
		}
	# No match found.
	# Copy this line to output buffer unchanged (restoring the
	# <carriage-return> if there was one).
	o[FNR] = $0 cr
}

even though there is no condition is only executed for input files after the 1st input file (and in this code there are only two input files). This group copies the input records as they are read into an output buffer array (o[]) with the index in the array being the current input file record number after searching for and updating any lines that contain the key strings created from lines found in the 1st input file.

The fourth group:

Code:

END {	# If any changes were made, copy the new contents of the second file
	# back into that file.
	if(mod)
		for(i = 1; i <= FNR; i++)
			print o[i] > FILENAME
}

with the action END (as described before) evaluates to FALSE for every line read from the two input files and is only processed after end-of-file is reached on both input files. As noted in the comments, this group copies the accumulated output buffer back into the last input file. The number of lines found in the last input file (FNR) and the pathname of the last input file (FILENAME) remain valid during any END actions.

Originally Posted by kttan

thank you for very details explanation.

sorry i'm still have 1 newb question.

is that able to skip awk and move to other awk if meet condition ?
because im still new and very confuse on those syntax, now i'm doing multiple awk to let it work.

i want something like

Code:

  if(A == 1) then 
     awk '{content}' 
  else 
     awk '{content}'
  end if

currently i'm use the method is write a file with some information and let next awk code use as variable, and then only remove the file.

Moderator's Comments:

Please use CODE tags when displaying sample input, output, and code segments as required by forum rules.

is that able to skip awk and move to other awk if meet condition ?

Originally Posted by Don Cragun

I don't know what:

means. I have no idea why you would want to run two seemingly identical awk programs instead of using A == 1 as a condition for the single action (named content in your pseudo-code) in both of your awk scripts.

You said that you're writing a file and let the next awk use something unspecified as a variable, but your code doesn't show that any variables or files are being passed to either of the awk scripts in your pseudo-code.

If there is something in the code I suggested that you don't understand, I'll be happy to try to answer specific questions. If you're just saying that my code is too complex and you don't want to try to understand what it is doing, I'm sorry that I have wasted your time and mine trying to help you.

Originally Posted by kttan

sorry for poor english , i'm din't mean that your code is complex and i'm dont want to understand, it very great explanation for your code.

the question i'm asking is difference question regrading the question i'm asking previously, but i'm don't want open another topic , scare it become spam topic.

.
.
.
so i'm asking is that any method for 2 awk share same variable, instate of create new file as a variable.

below is a part from my script.
i have 2 type of condition.
1. if temp.rpt is empty then it will empty the content for board_temp (by using print "" >board_temp, so with this step will making the next awk "look like skip" , and go to 3rd awk.
2. if temp.rpt have content then proceed with next awk.
.
.
.