Shell Programming and Scripting

100 1
200 1
300 4
100 2
200 3
300 4
100 9
200 8
300 7

100 200 300
 1     1    4
 2     3    4
 9     8    7

awk '{if(!($1 in A)){C[++o]=$1;};++A[$1];B[$1,A[$1]]=$NF;P=P>A[$1]?P:A[$1]} END{for(f=1;f<=o;f++){printf("%d\t",C[f])};print X;for(j=1;j<=P;j++){for(l=1;l<=o;l++){printf("%d\t",B[C[l],j])};print X}}'   Input_file

100    200    300    
1    1    4    
2    3    4    
9    8    7

awk '{
        if(!($1 in A)){
                        C[++o]=$1;
                      };
        ++A[$1];
        B[$1,A[$1]]=$NF;
        P=P>A[$1]?P:A[$1]
     }
    END{
        for(f=1;f<=o;f++){
                                printf("%d\t",C[f])
                         };
        print X;
        for(j=1;j<=P;j++){
                                for(l=1;l<=o;l++){
                                                        printf("%d\t",B[C[l],j])
                                                 };
                         print X
                         }
       }
    '   Input_file

awk '
  {
    if($1 in A) {
      if(!c) c=p
    } 
    else 
      h=h $1 OFS
  } 
  c && !(p%c) {
    if(h) print h
    print s
    h=s=x
  }
  {
    A[$1]
    s=s $2 OFS
    p=FNR
  }
  END {
    print s
  }
' OFS='\t' file

awk '
BEGIN { format=" %-5s" }
function printA() {
# print the A indices once
  if (!header) {
    header=1
    for (i in A) printf format,i
    printf "\n"
  }
# print the A values
  for (i in A) printf format,A[i]
  printf "\n"
}

($1 in A) {
# repetition detected, print+clear the array
  printA()
  split("",A)
}

# store $2 in $1-indexed array
{ A[$1]=$2 }

# at the end print the array
END { printA() }
' inputfile

awk '			# Use awk to process the following script:
  {
    if($1 in A) {	# If the value in the 1st field has been seen before
      if(!c) c=p	#   if c has not been set, set it to p.  (Since p is
			#   later set to the previous input line number and $1
			#   will have been seen before and c will not have been
			#   set only when we see the 2nd occurrence of the 1st
			#   value in the 1st field, this sets c to the number
			#   of different values that appear in the 1st field.)
    } 
    else 		# otherwise (the value in the 1st field has not been
			# seen)
      h=h $1 OFS	#   add the 1st field and a field separator to the
			#   header string.
  } 
  c && !(p%c) {		# If c is non-zero and p is an even multiple of c
    if(h) print h	#   if h (the header line) is not an empty string print
			#   it,
    print s		#   print the string of accumulated $2 values, and
    h=s=x		#   clear the header line and the string of accumulated
			#   $2 values.
  }
  {
    A[$1]		# Record that we have seen this $1 value before,
    s=s $2 OFS		# add the current $2 value to the string of accumulated
			# $2 values, and
    p=FNR		# set p to the current input line number.
  }
  END {
    print s		# When we hit EOF on the input file, print the last
			# string of accumulated $2 values.
  }
' OFS='\t' file		# Mark the end of the awk script text, set the output
			# field separator to a tab and name the input file to
			# be processed.

c

If c is non-zero and p is an even multiple of c