Shell Programming and Scripting

OK. The following ksh script will also work with bash.
OK. The following ksh/awk script will report ties.
OK. The following script just doesn't create those files.
It doesn't create any files that won't be created by later steps in your code. And, more importantly, if files already exist with those names, it won't discard data created in earlier runs. The touch commands in that loop don't do anything but set the timestamps on those files to the current time if the files exist, or create them if they don't already exist. This loop does not put any data in any of those files.
My crystal ball isn't good enough to guess at what you might want to do but haven't specified. The following code does produce some output you said you wanted that I don't see being produced by your script.
Maybe this script:

Code:

#!/bin/ksh
awk -F, '
FNR > 1 {
	total_sales += $4
	if(++count[$1] > mc)
		mc = count[$1]
	if((quantity[$1] += $2) > mq)
		mq = quantity[$1]
	if((sales[$1] += $4) > ms)
		ms = sales[$1]
}
END {	printf("Total sales for today is : %.2f\n\n", total_sales)
	for(item in quantity)
	    if(quantity[item] == mq)
		printf("%s is the highest selling item with quantity : %d\n",
		    item, mq)
	print ""
	for(item in count)
	    if(count[item] == mc)
	    	printf("%s had the most times sold : %d\n", item, mc)
	print ""
	for(item in sales)
	    if(sales[item] == ms)
	    	printf("%s had the highest income : %.2f\n", item, sales[item])
}' log

which, with your sample data produces the output:

Code:

Total sales for today is : 35.50

sugar is the highest selling item with quantity : 5
coffee is the highest selling item with quantity : 5

tea had the most times sold : 2
coffee had the most times sold : 2

coffee had the highest income : 20.00

(but the order of the output of items in each section of the output may vary with different version of awk) will give you an idea of how to report similar results for other questions that might arise from your data.

This will work as is on both Red Hat and AIX. If someone wants to try this on a Solaris/SunOS system, change awk to /usr/xpg4/bin/awk or nawk.

Note that it only reads your data file once and produces no temporary files. The awk code used in this script is pretty straight forward. If you don't understand how it works (after looking at the awk man page), feel free to ask questions.

Hi Don,

Thank you very much for the script, it is working as it should be.

Since my knowledge on awk is minimal, i was not able to understand the script...could you please explain the script in your free time for our benefit.

cheers...

regards,
bhupesh

Hi bhupesh,
Did you look at the awk man page on your system? (i.e., run the command man awk?)

I would be happy to try to explain any part of that script that you are having trouble understanding. What part(s) of the script were you not able to understand?

- Don