Shell Programming and Scripting

1000/3333,20150101-96
1000/4444,20150102-02
1000/5555,20150103-29
1000/6666,20150104-67

1000/3333
9999/9999

1000/6666
8888/8888

1000/3333,20150101-96
9999/9999

1000/6666,20150104-67
8888/8888

#!/bin/bash
INPUTFILE="/home/username/blah/file1"
DATAFILE="/home/username/blah/file2"
OUTFILE="/home/username/pleasework.out"

awk 'BEGIN {
while (getline < "'"$INPUTFILE"'")
{
split($0,a,",");
name=a[1];
date=a[2];

key=date
data=name
nameofarray[data]=key;
}
close("'"$INPUTFILE"'");

while (getline < "'"$DATAFILE"'")
{
var=nameofarray[$0];
print $0","var > "'"$OUTFILE"'"; 
}
}'

#!/bin/bash
# Move to the directory where the input files are located.
cd "/home/username/blah"

awk '
BEGIN {	# Set input and output field separators.
	FS = OFS = ","
}
FNR == NR {
	# Get keys from 1st input file.
	key[$1] = $2
	next
}
function copyback() {
	# After we have read the last line of input from a file, rewrite it
	# with updated contents if anything was changed.
	if(nc) {
		for(i = 1; i <= lines; i++)
			print d[i] > filename
		close(filename)
	}
}
FNR == 1 {
	# When we see the first line of subsequent files, update the previous
	# input file...
	copyback()
	# and get ready for the current input file...
	filename = FILENAME
	lines = nc = 0
}
{	# Gather data from current input file...
	if($1 in key) {
		# Add data gathered from first input file
		d[++lines] = $1 OFS key[$1]
		# Increment the number of changes made.
		nc++
	} else {	# Just save the input line unchanged.
		d[++lines] = $0
	}
}
END {	# When we hit EOF on the last input file, update the last input file...
	copyback()
}' file1 file2 file3