Shell Programming and Scripting

USS|AWCC|AFGAW|93|70
USSAA|Roshan TDCA|AFGTD|93|72,79
ALB|Vodafone|ALBVF|355|69
ALGEE|Wataniya (Nedjma)|DZAWT|213|50,550

USS|AWCC|AFGAW|93|9370
USSAA|Roshan TDCA|AFGTD|93|9372,9379
ALB|Vodafone|ALBVF|355|35569
ALGEE|Wataniya (Nedjma)|DZAWT|213|21350,213550

awk -vs1="," -F"|" '{A=$(NF-1);split($NF, B,",");for(i in B){C=C?C s1 A B[i]:A B[i];$NF=C;}C=""} 1' OFS="|"  Input_file

USS|AWCC|AFGAW|93|9370
USSAA|Roshan TDCA|AFGTD|93|9372,9379
ALB|Vodafone|ALBVF|355|35569
ALGEE|Wataniya (Nedjma)|DZAWT|213|21350,213550

awk -v FromField=4 -v ToField=5 '
BEGIN {	FS = OFS = "|"
}
{	n = split($ToField, f, /,/)
	o = ""
	for(i = 1; i <= n; i++)
		o = o $FromField f[i] (i < n ? "," : "")
	$ToField = o
}
1' file

awk -vs1="," -F"|" '{           ######## taking a variable named s1 whose value is comma(,) and setting field separator to |
A=$(NF-1);                      ######## Now making a variable named A whose value is the second last field's value.
split($NF, B,",");              ######## Now using split function I am splitting value of last column $NF and storing it to an array named B with delimiter comma(,).
for(i in B){                    ######## Now going into elements of array B
C=C?C s1 A B[i]:A B[i];         ######## now creating a variable named C whose value is array A's value with array B's value, it is keep appending if it has more than one values to it into C variable by conditional operators ? and :
$NF=C;}                         ######## Now making $NF(last field's) value to variable C's value.
C=""}                           ######## Now nullifying the value of variable C.
1'                              ######## awk works on method of condition and then pattern, here I am mentioning 1 which means condition is TRUE and no action so default action will occur which is printing the line.
OFS="|" Input_file              ######## mentioning the output field seprator to | and mentioning Input_file name.

$ awk -F"|" -v OFS="|" ' $NF { $NF=","$NF; gsub(",",","$(NF-1),$NF); sub(",","",$NF) } 1 ' file
USS|AWCC|AFGAW|93|9370
USSAA|Roshan TDCA|AFGTD|93|9372,9379
ALB|Vodafone|ALBVF|355|35569
ALGEE|Wataniya (Nedjma)|DZAWT|213|21350,213550