Shell Programming and Scripting

It looks like vgersh99 had a simple off by one error in the awk print statement's arguments that you have copied into your current script. Try the following instead:

Code:

#!/bin/bash
awk '
BEGIN {	FS = OFS = ","
	print "SourceFile", "AirSpeed", "GPSLatitude", "GPSLongitude", "Altitude"
}
FNR == NR && FNR > 1 {
	f1[$NF] = $1
	next
}
{	idx = $1 " " $2
	gsub("/",  ":", idx)
	if(idx in f1)
		print f1[idx], $3, $4, $5, $6
}' file1.csv file2.csv > file4.csv

With file1.csv containing what you said was in file1 and file2.csv containing what you said was in file2 in post #1 in this thread, this script writes the following into file4.csv:

Code:

SourceFile,AirSpeed,GPSLatitude,GPSLongitude,Altitude
/home/intannf/foto/IMG_0677.JPG,0.,-7.77075,110.35782,6.34 
/home/intannf/foto/IMG_0759.JPG,0.,-7.77075,110.35782,6.31 
/home/intannf/foto/IMG_0771.JPG,0.,-7.77075,110.35782,6.20

which seems to be what you wanted, except there are some trailing spaces caused by copying trailing spaces from your sample file2.

This should work with awk or gawk or mawk on most systems. If you want to try this on a Solaris/SunOS system, change awk to /usr/xpg4/bin/awk.

You can turn this into a 1-liner if you want to, but I prefer readable code.

Hi, Don Cragun

Thanks for your help. I have tried to run your code and it works successfully! Thank you so much!

Regards,
Intan