Shell Programming and Scripting

I said printf not print

Oops ! My apologies, Yoda.

elixir sinari is right about the problem that he pointed out.

So use this code instead:

Code:

awk 'NR==FNR{A[$1];next}{for(i=1;i<=NF;i++) { if( !( i in A )) printf $i OFS } printf "\n" }' nofields input

I'm surprised this works for you. If nofields contains:

Code:

1
3
5

and input contains:

Code:

1 2 3 4 5
1 2 3 4 5 6 7 
1 2 3 4
1
1 2
1 2 3

the output I get is:

Code:

2 4 2 4 6 7
2 4
2
2

where the first two lines are joined, the last line is incomplete (ending with a <space> instead of a <newline>), and the input line that just contained one field was deleted (where I expected you wanted an empty line) as follows:

Code:

2 4
2 4 6 7
2 4

2
2

where each line is terminated by a <newline> and there is never a <space> immediately before any line's terminating <newline>. If this is what you want, you could try something like:

Code:

nawk '
NR == FNR {
        a[$1]
        next
}
{       first=0
        for(i = 1; i <= NF; i++)
                if(!(i in a))
                        printf("%s%s", first++ ? FS : "", $i)
        print ""
}' nofields input

or, if you insist on a much less readable single line version:

Code:

nawk 'NR==FNR{a[$1];next}{f=0;for(i=1;i<=NF;i++)if(!(i in a))printf("%s%s",f++?FS:"",$i);print ""}' nofields input

I am not a fan of one-liners!

Note that Yoda's script will take care of most of the issues discussed here, but will still sometimes print a field separator at the end of line (before the terminating <newline>).

I didn't faced this problem .. might be due the fact that my input file had all the rows with same number of fields in it... and last field is not in nofields file.
But I must appreciate you for forcing my mind to rethink about this one-liner...

@Yoda
I would have replaced printf "\n" with print ""

This code silently converts %% into % and will implode if a % is present and not followed by another %.

Regards,
Alister