Shell Programming and Scripting

Index folder 

chr1

1
2
3
5
6

chr2

1
2
3
4
5
7

chr3

1
5
7


Data Folder 

Subfolder1

chr1

1
0
1
0
0

chr2

0
1
0
1
0
1

chr3

0
0
2

Subfolder2

chr1

1
1
2
2
3

chr2

1
3
4
6
0
0


chr3

1
0
0

Output

		Subfolder1	Subfolder2
chr1	1	1	1
chr1	2	0	1
chr1	3	1	2
chr1	5	0	2
chr1	6	0	3
chr2	1	0	1
chr2	2	1	3
chr2	3	0	4
chr2	4	1	6
chr2	5	0	0
chr2	7	1	0
chr3	1	0	1
chr3	5	0	0
chr3	7	2	0

find index data -type f -print | awk '
/^index/ {
   FL=$0
   n=split(FL,p,"/");
   F[++files]=p[n]
   n=0
   while ((getline < FL) > 0) {
       I[F[files],++n]=$0
       C[F[files]]=n
   }
   close(FL)
}
/^data/ { FL=$0
   n=split(FL,p,"/");
   subdir=p[n-1]
   S[subdir]=1
   file=p[n]
   n=0
   while ((getline < FL) > 0)
      D[file,subdir,++n]=$0
   close(FL)
}
END{
    printf "\t"
    for(subdir in S) printf "\t%s",subdir;
    printf "\n"
    for(i=1;i<=files;i++) {
        for(c=1;c<=C[F[i]];c++) {
            printf "%s\t%s",F[i],I[F[i],c]
            for(subdir in S) printf "\t%s",D[F[i],subdir,c];
            printf "\n"
        }
    }
}'

find index data -type f -print | awk -F/ '
/^index/ { F[++files]=$NF }
/^data/  { S[$(NF-1)] }
END {
    printf "\t"
    for(subdir in S) printf "\t%s",subdir;
    printf "\n"
    for(i=1;i<=files;i++) {
        while((getline < ("index/"F[i])) > 0) {
            printf "%s\t%s",F[i],$0
            for(subdir in S) {
                getline < ("data/"subdir"/"F[i])
                printf "\t%s",$0
            }
            printf "\n"
        }
        close(F[i])
        for(subdir in S) close("data/"subdir"/"F[i]);
    }
}'