Shell Programming and Scripting

#!/usr/bin/awk -f

# TAB delimited
BEGIN { FS="\t" }

# skip header
NR==1 { next }

# strip DOS line endings
{sub(/\r$/,"")}

# keep list of unique genes, in order
!($1 in genes_by_name) { genes_by_name[$1]=genes_idx; genes_by_num[genes_idx++]=$1; }

{
        # unquote
        gsub(/(^"|"$)/,"",$2)
        split($2, cols, /,/)
        for (col in cols) {
                # keep list of unique samples, in order
                if (! (cols[col] in samples_by_name)) {
                        samples_by_name[cols[col]]=samples_idx
                        samples_by_num[samples_idx++]=cols[col]
                }
                matrix[$1,cols[col]] = matrix[$1,cols[col]] "," $3
        }
}

END {
        # print header
        printf("gene\t")
        for (i = 0; i < samples_idx; i++)
                printf("%s\t", samples_by_num[i])
        printf("\n")

        for (i = 0; i < genes_idx; i++) {
                printf("%s\t", genes_by_num[i]);
                for (j = 0; j < samples_idx; j++)
                        printf("%s\t", substr(matrix[genes_by_num[i],samples_by_num[j]],2))
                printf("\n")
        }
}

f = open('/path/to/input/file.txt' , 'r')
matrix={}
f.readline()
for line in f:
	(gene,sample,id) = line.split()
	sample = sample.split(',')
	for sam in sample:
		matrix.setdefault(gene,{}).setdefault(sam,[]).append(id)

The Output is:-
print(matrix)
>>> {'a': {'1': ['@']}, 'c': {'3': ['@'], '4': ['@']}, 'b': {'2': ['#']}, 'd': {'5': ['%', '*']}}