Shell Programming and Scripting

ls VOD[0-9]*.pdf | awk '
    NF > 1 {        # assume spaces
        of = $0;
        split( $NF, a, "." );
        n = split( $0, b, " " );
        b[n] = a[1];
        sep = " ";
    }

    NF == 1 {       # assume underbars
        of = $1;
        split( $1, a, "." );
        n = split( a[1], b, "_" );
        sep = "_";
    }

    {
        printf( "mv \"%s\"  \"%s", of, b[n] );
        for( i = 2; i < n; i++ )
            printf( "%s%s", sep, b[i] );
        printf( ".%s\"\n", a[2] );
    }

' #| ksh

for i in VOD*.*pdf; do mv "$i" "$(echo "$i"|sed 's/[^_ ]*[_ ]*\([^_ ]*\)[_ ]*\([^_ ]*\)[_ ]*\([^_ ]*\)\(\..*\)/\3 \1 \2\4/')"; done

ls VOD[0-9]*.pdf | awk '
    NF > 1 {        # input line will have more than one field if filename has spaces
        of = $0;                    # save the original filename
        split( $NF, a, "." );       # split the last part of filename into array a using dot as seperator
        n = split( $0, b, " " );    # easy way to get all of the fields into an array
                                    # we put the fields into an array so we can treat both cases identically later
        b[n] = a[1];                # replace last field xxxx.yyyy with just xxxx
        sep = " ";                  # seperator to use when building the move to file
    }

    NF == 1 {                       # if just one field, asssume a filename without spaces
        of = $1;                    # save the original name
        split( $1, a, "." );        # split the name (xxx_yyy_zzzz.eee) on the dot xxx_yyy_zzzz goes into a[1] eee into a[2]
        n = split( a[1], b, "_" );  # split the leading lead part into array b using _ as separator
        sep = "_";                  # seperator to use when building the move to file
    }

      {                               # this block executed for all files; assumes array b has the filename components and n is the size of b
        printf( "mv \"%s\"  \"%s", of, b[n] );      # print command (mv) original name and  the last component of the name
          for( i = 2; i < n; i++ )   # starting with second component in the name print up to, but not including the last component
            printf( "%s%s", sep, b[i] );
        printf( ".%s\"\n", a[2] );      # add the extension (.xxx) and a newline
    }
' #| ksh