Shell Programming and Scripting

awk -F, '{print $1,$2,$4,$18,$20}'

$ cat script.pl
use warnings;
use strict;

@ARGV >= 3 or die <<USAGE;
Usage: perl $0 file_separator #column #column #column ... file
Example: perl $0 "," 7 12 41 myfile.csv
USAGE

## Get arguments:
## First one ($file_separator) -> Separator of csv file.
## Last one ($file) -> The file to process.
## Rest of arguments (@columns) -> The numbers of the columns to print.
my $file_separator = shift;
my $file = pop @ARGV;
my @columns = grep { /^\d+$/ } @ARGV;

open my $fh, "<", $file or die "Cannot open file $file: $!\n";

## Index of columns begin in 0.
@columns = map { --$_ } @columns;

while ( <$fh> ) {

        ## Omit blank lines.
        next unless /\S/;

        ## Remove end of line character.
        chomp;

        ## Once in the processing of the file, count number of fields and remove
        ## from the array of columns those number bigger or incorrect (not
        ## positives).
        if ( 1 .. 1 ) {
                my $line_fields = eval "tr/$file_separator/$file_separator/";
                ++$line_fields;
                @columns = grep { $_ < $line_fields && $_ >= 0  } @columns; 
        }

        ## Split columns and join only those pointed out in parameters.
        my @line_columns = split /$file_separator/;
        my $outline = join "$file_separator", @line_columns[ @columns ];
        printf "%s\n", $outline;
}

close $fh or warn "Cannot close file $file: $!\n";
$ perl script.pl
Usage: perl script.pl file_separator #column #column #column ... file
Example: perl script.pl "," 7 12 41 myfile.csv
$ perl script.pl "," 1 4 7 36 infile
... ((Output)) ...