Shell Programming and Scripting

sh script file1 filea fileb filec ................filez. >>output1 & output2 &output3

z10     1873    1920    z_number1_E59
z10     2042    2090    z_number2_E59
Z22     2476    2560    z_number3_E59
Z22     2838    2915    z_number4_E59
z1      1873    1920    z_number1_E60
z1      2042    2090    z_number2_E60
z1      2032    2041    z_number2_E20

z10     1873    1920    z_number1_E59
z10     2042    2090    z_number2_E59
Z22     2476    2560    z_number3_E59
Z22     2838    2915    z_number4_E59
z1      1863    1872    z_number1_E60
z1      2032    2041    z_number2_E60
z1      2032    2041    z_number2_E10

z10     1863    1872    z_number1_E59
z10     2032    2041    z_number2_E59
Z22     2476    2560    z_number3_E59
Z22     2838    2915    z_number4_E59
z1      1873    1920    z_number1_E60
z1      2042    2090    z_number2_E60
z1      2032    2041    z_number2_E10

z10     1873    1920    z_number1_E59
z10     2042    2090    z_number2_E59
Z22     2476    2560    z_number3_E59
Z22     2838    2915    z_number4_E59
z1      1863    1872    z_number1_E60
z1      2032    2041    z_number2_E60
z1      2032    2041    z_number2_E10

Z22     2476    2560    z_number3_E59
Z22     2838    2915    z_number4_E59

z1      2032    2041    z_number2_E10

z1      2032    2041    z_number2_E20

awk -v nfiles="4" 'NR==FNR{a[$0]++;next}
$0 in a {a[$0]++; next}
{b[$0]++}
END{
  for(i in a){
    if(a[i]==nfiles) {
      print i > "output1"
    }
    else if(a[i]==1) {
        print i > "output3"
    }
  }
  for(i in b){
    if(b[i]==nfiles-1) {
        print i > "output2"
    }
  }
}' file1 filea fileb filec

$0 in a {a[$0]++; next}		# This counts the number of each line in an array

    if(a[i]==nfiles) {		# If the value of an element == 4
      print i > "output1"	# ++ the line exists in 4 files
    }

awk -v nfiles="4" '
NR==FNR{a[$0]++;next}           # NR is the current record number counting from start of programme
                                # FNR is the current record number counting from start of current file
                                # when FNR == NR it implies the record comes from file 1
                                # thus this statement captures all records from file 1 in the hash named 'a'
                                # the index is the whole input record with the value being a count of files.
                                # next causes the next record to be read and the programme to loop to top

$0 in a {a[$0]++; next}         # when this statement is reached, the record ($0) is not in the first file
                                # if the current record was seen in the first file increment the counter
                                # maintained in a.  Next causes the next record to be read.

{b[$0]++}                       # this statement is executed when a record from file2...n is encountered
                                # and the record was not seen in file1. A second hash is used to
                                # track all records that weren't in file 1

END{                            # this section of code is driven after the last record is read from file n
   for(i in a){                 # for every record seen in file 1...
      if(a[i]==nfiles) {        # if the record was seen in all files (count in a matches number of files)
         print i > "output1"    # print to the list for seen in all files
      }
      else if(a[i]==1) {        # if the record was only seen in the first file print to output list
         print i > "output3"     # of records just in file 1
      }
  }

  for(i in b){                  # for every record that wasn't seen in the  first file, but was seen
     if(b[i]==nfiles-1) {       # in all other files, print to that list
        print i > "output2"
     }
 }
}' file1 filea fileb filec