Unix/Linux Go Back    


RedHat 9 (Linux i386) - man page for time::hires (redhat section 3)

Linux & Unix Commands - Search Man Pages
Man Page or Keyword Search:   man
Select Man Page Set:       apropos Keyword Search (sections above)


HiRes(3)		       User Contributed Perl Documentation			 HiRes(3)

NAME
       Time::HiRes - High resolution alarm, sleep, gettimeofday, interval timers

SYNOPSIS
	 use Time::HiRes qw( usleep ualarm gettimeofday tv_interval );

	 usleep ($microseconds);

	 ualarm ($microseconds);
	 ualarm ($microseconds, $interval_microseconds);

	 $t0 = [gettimeofday];
	 ($seconds, $microseconds) = gettimeofday;

	 $elapsed = tv_interval ( $t0, [$seconds, $microseconds]);
	 $elapsed = tv_interval ( $t0, [gettimeofday]);
	 $elapsed = tv_interval ( $t0 );

	 use Time::HiRes qw ( time alarm sleep );

	 $now_fractions = time;
	 sleep ($floating_seconds);
	 alarm ($floating_seconds);
	 alarm ($floating_seconds, $floating_interval);

	 use Time::HiRes qw( setitimer getitimer
			     ITIMER_REAL ITIMER_VIRTUAL ITIMER_PROF ITIMER_REALPROF );

	 setitimer ($which, $floating_seconds, $floating_interval );
	 getitimer ($which);

DESCRIPTION
       The "Time::HiRes" module implements a Perl interface to the usleep, ualarm, gettimeofday,
       and setitimer/getitimer system calls. See the EXAMPLES section below and the test scripts
       for usage; see your system documentation for the description of the underlying nanosleep
       or usleep, ualarm, gettimeofday, and setitimer/getitimer calls.

       If your system lacks gettimeofday(2) or an emulation of it you don't get gettimeofday() or
       the one-arg form of tv_interval().  If you don't have nanosleep() or usleep(3) or
       select(2) you don't get Time::HiRes::usleep() or sleep().  If your system don't have
       ualarm(3) or setitimer(2) you don't get Time::HiRes::ualarm() or alarm().

       If you try to import an unimplemented function in the "use" statement it will fail at com-
       pile time.

       If your subsecond sleeping is implemented with nanosleep() instead of usleep(), you can
       mix subsecond sleeping with signals since nanosleep() does not use signals.  This, how-
       ever, is unportable behavior, and you should first check for the truth value of
       &Time::HiRes::d_nanosleep to see whether you have nanosleep, and then read carefully your
       nanosleep() C API documentation for any peculiarities.  (There is no separate interface to
       call nanosleep(); just use Time::HiRes::sleep() or usleep() with small enough values.
       Also, think twice whether using nanosecond accuracies in a Perl program is what you should
       be doing.)

       The following functions can be imported from this module.  No functions are exported by
       default.

       gettimeofday ()
	   In array context returns a 2 element array with the seconds and microseconds since the
	   epoch.  In scalar context returns floating seconds like Time::HiRes::time() (see
	   below).

       usleep ( $useconds )
	   Sleeps for the number of microseconds specified.  Returns the number of microseconds
	   actually slept.  Can sleep for more than one second unlike the usleep system call. See
	   also Time::HiRes::sleep() below.

       ualarm ( $useconds [, $interval_useconds ] )
	   Issues a ualarm call; interval_useconds is optional and will be 0 if unspecified,
	   resulting in alarm-like behaviour.

       tv_interval
	   "tv_interval ( $ref_to_gettimeofday [, $ref_to_later_gettimeofday] )"

	   Returns the floating seconds between the two times, which should have been returned by
	   gettimeofday(). If the second argument is omitted, then the current time is used.

       time ()
	   Returns a floating seconds since the epoch. This function can be imported, resulting
	   in a nice drop-in replacement for the "time" provided with core Perl, see the EXAMPLES
	   below.

	   NOTE 1: this higher resolution timer can return values either less or more than the
	   core time(), depending on whether your platforms rounds the higher resolution timer
	   values up, down, or to the nearest to get the core time(), but naturally the differ-
	   ence should be never more than half a second.

	   NOTE 2: Since Sunday, September 9th, 2001 at 01:46:40 AM GMT (when the time() seconds
	   since epoch rolled over to 1_000_000_000), the default floating point format of Perl
	   and the seconds since epoch have conspired to produce an apparent bug: if you print
	   the value of Time::HiRes::time() you seem to be getting only five decimals, not six as
	   promised (microseconds).  Not to worry, the microseconds are there (assuming your
	   platform supports such granularity).  What is going on is that the default floating
	   point format of Perl only outputs 15 digits.  In this case that means ten digits
	   before the decimal separator and five after.  To see the microseconds you can use
	   either printf/sprintf with "%.6f", or the gettimeofday() function in list context,
	   which will give you the seconds and microseconds as two separate values.

       sleep ( $floating_seconds )
	   Sleeps for the specified amount of seconds.	Returns the number of seconds actually
	   slept (a floating point value).  This function can be imported, resulting in a nice
	   drop-in replacement for the "sleep" provided with perl, see the EXAMPLES below.

       alarm ( $floating_seconds [, $interval_floating_seconds ] )
	   The SIGALRM signal is sent after the specified number of seconds.  Implemented using
	   ualarm().  The $interval_floating_seconds argument is optional and will be 0 if
	   unspecified, resulting in alarm()-like behaviour.  This function can be imported,
	   resulting in a nice drop-in replacement for the "alarm" provided with perl, see the
	   EXAMPLES below.

	   NOTE 1: With some platform - Perl release combinations select() gets restarted by
	   SIGALRM, instead of dropping out of select().  This means that an alarm() followed by
	   a select() may together take the sum of the times specified for the the alarm() and
	   the select(), not just the time of the alarm().

       setitimer
	   "setitimer ( $which, $floating_seconds [, $interval_floating_seconds ] )"

	   Start up an interval timer: after a certain time, a signal arrives, and more signals
	   may keep arriving at certain intervals.  To disable a timer, use time of zero.  If
	   interval is set to zero (or unspecified), the timer is disabled after the next deliv-
	   ered signal.

	   Use of interval timers may interfere with alarm(), sleep(), and usleep().  In stan-
	   dard-speak the "interaction is unspecified", which means that anything may happen: it
	   may work, it may not.

	   In scalar context, the remaining time in the timer is returned.

	   In list context, both the remaining time and the interval are returned.

	   There are usually three or four interval timers available: the $which can be
	   ITIMER_REAL, ITIMER_VIRTUAL, ITIMER_PROF, or ITIMER_REALPROF.  Note that which ones
	   are available depends: true UNIX platforms have usually all first three, but for exam-
	   ple Win32 and Cygwin only have ITIMER_REAL, and only Solaris seems to have
	   ITIMER_REALPROF (which is used to profile multithreaded programs).

	   ITIMER_REAL results in alarm()-like behavior.  Time is counted in real time, that is,
	   wallclock time.  SIGALRM is delivered when the timer expires.

	   ITIMER_VIRTUAL counts time in (process) virtual time, that is, only when the process
	   is running.	In multiprocessor/user/CPU systems this may be more or less than real or
	   wallclock time.  (This time is also known as the user time.)  SIGVTALRM is delivered
	   when the timer expires.

	   ITIMER_PROF counts time when either the process virtual time or when the operating
	   system is running on behalf of the process (such as I/O).  (This time is also known as
	   the system time.)  (Collectively these times are also known as the CPU time.)  SIGPROF
	   is delivered when the timer expires.  SIGPROF can interrupt system calls.

	   The semantics of interval timers for multithreaded programs are system-specific, and
	   some systems may support additional interval timers.  See your setitimer() documenta-
	   tion.

       getitimer ( $which )
	   Return the remaining time in the interval timer specified by $which.

	   In scalar context, the remaining time is returned.

	   In list context, both the remaining time and the interval are returned.  The interval
	   is always what you put in using setitimer().

EXAMPLES
	 use Time::HiRes qw(usleep ualarm gettimeofday tv_interval);

	 $microseconds = 750_000;
	 usleep $microseconds;

	 # signal alarm in 2.5s & every .1s thereafter
	 ualarm 2_500_000, 100_000;

	 # get seconds and microseconds since the epoch
	 ($s, $usec) = gettimeofday;

	 # measure elapsed time
	 # (could also do by subtracting 2 gettimeofday return values)
	 $t0 = [gettimeofday];
	 # do bunch of stuff here
	 $t1 = [gettimeofday];
	 # do more stuff here
	 $t0_t1 = tv_interval $t0, $t1;

	 $elapsed = tv_interval ($t0, [gettimeofday]);
	 $elapsed = tv_interval ($t0); # equivalent code

	 #
	 # replacements for time, alarm and sleep that know about
	 # floating seconds
	 #
	 use Time::HiRes;
	 $now_fractions = Time::HiRes::time;
	 Time::HiRes::sleep (2.5);
	 Time::HiRes::alarm (10.6666666);

	 use Time::HiRes qw ( time alarm sleep );
	 $now_fractions = time;
	 sleep (2.5);
	 alarm (10.6666666);

	 # Arm an interval timer to go off first at 10 seconds and
	 # after that every 2.5 seconds, in process virtual time

	 use Time::HiRes qw ( setitimer ITIMER_VIRTUAL time );

	 $SIG{VTLARM} = sub { print time, "\n" };
	 setitimer(ITIMER_VIRTUAL, 10, 2.5);

C API
       In addition to the perl API described above, a C API is available for extension writers.
       The following C functions are available in the modglobal hash:

	 name		  C prototype
	 ---------------  ----------------------
	 Time::NVtime	  double (*)()
	 Time::U2time	  void (*)(UV ret[2])

       Both functions return equivalent information (like "gettimeofday") but with different rep-
       resentations.  The names "NVtime" and "U2time" were selected mainly because they are oper-
       ating system independent.  ("gettimeofday" is Un*x-centric.)

       Here is an example of using NVtime from C:

	 double (*myNVtime)();
	 SV **svp = hv_fetch(PL_modglobal, "Time::NVtime", 12, 0);
	 if (!svp)	   croak("Time::HiRes is required");
	 if (!SvIOK(*svp)) croak("Time::NVtime isn't a function pointer");
	 myNVtime = INT2PTR(double(*)(), SvIV(*svp));
	 printf("The current time is: %f\n", (*myNVtime)());

CAVEATS
       Notice that the core time() maybe rounding rather than truncating.  What this means that
       the core time() may be giving time one second later than gettimeofday(), also known as
       Time::HiRes::time().

AUTHORS
       D. Wegscheid <wegscd@whirlpool.com> R. Schertler <roderick@argon.org> J. Hietaniemi
       <jhi@iki.fi> G. Aas <gisle@aas.no>

COPYRIGHT AND LICENSE
       Copyright (c) 1996-2002 Douglas E. Wegscheid.  All rights reserved.

       Copyright (c) 2002 Jarkko Hietaniemi.  All rights reserved.

       This program is free software; you can redistribute it and/or modify it under the same
       terms as Perl itself.

perl v5.8.0				    2002-10-13					 HiRes(3)
Unix & Linux Commands & Man Pages : ©2000 - 2018 Unix and Linux Forums


All times are GMT -4. The time now is 11:35 AM.