eval(n) [osx man page]

eval(n) 						       Tcl Built-In Commands							   eval(n)

__________________________________________________________________________________________________________________________________________________

NAME

       eval - Evaluate a Tcl script

SYNOPSIS

       eval arg ?arg ...?
_________________________________________________________________

DESCRIPTION

       Eval  takes  one  or more arguments, which together comprise a Tcl script containing one or more commands.  Eval concatenates all its argu-
       ments in the same fashion as the concat command, passes the concatenated string to the Tcl interpreter recursively, and returns the  result
       of  that  evaluation  (or any error generated by it).  Note that the list command quotes sequences of words in such a way that they are not
       further expanded by the eval command.

EXAMPLES

       Often, it is useful to store a fragment of a script in a variable and execute it later on with extra values  appended.  This  technique	is
       used  in  a  number of places throughout the Tcl core (e.g. in fcopy, lsort and trace command callbacks). This example shows how to do this
       using core Tcl commands:
	      set script {
		  puts "logging now"
		  lappend $myCurrentLogVar
	      }
	      set myCurrentLogVar log1
	      # Set up a switch of logging variable part way through!
	      after 20000 set myCurrentLogVar log2

	      for {set i 0} {$i<10} {incr i} {
		  # Introduce a random delay
		  after [expr {int(5000 * rand())}]
		  update    ;# Check for the asynch log switch
		  eval $script $i [clock clicks]
	      }

       Note that in the most common case (where the script fragment is actually just a list of words forming a command prefix), it  is	better	to |
       use  {*}$script	when  doing this sort of invocation pattern.  It is less general than the eval command, and hence easier to make robust in |
       practice.  The following procedure acts in a way that is analogous to the lappend command, except it inserts the  argument  values  at  the
       start of the list in the variable:
	      proc lprepend {varName args} {
		 upvar 1 $varName var
		 # Ensure that the variable exists and contains a list
		 lappend var
		 # Now we insert all the arguments in one go
		 set var [eval [list linsert $var 0] $args]
	      }
       However, the last line would now normally be written without eval, like this:								   |
	      set var [linsert $var 0 {*}$args] 												   |

SEE ALSO

       catch(n), concat(n), error(n), interp(n), list(n), namespace(n), subst(n), tclvars(n), uplevel(n)

KEYWORDS

       concatenate, evaluate, script

Tcl																	   eval(n)

uplevel(n)						       Tcl Built-In Commands							uplevel(n)

__________________________________________________________________________________________________________________________________________________

NAME

       uplevel - Execute a script in a different stack frame

SYNOPSIS

       uplevel ?level? arg ?arg ...?
_________________________________________________________________

DESCRIPTION

       All  of the arg arguments are concatenated as if they had been passed to concat; the result is then evaluated in the variable context indi-
       cated by level.	Uplevel returns the result of that evaluation.

       If level is an integer then it gives a distance (up the procedure calling stack) to move before executing the command.  If  level  consists
       of  #  followed	by  a  number then the number gives an absolute level number.  If level is omitted then it defaults to 1.  Level cannot be
       defaulted if the first command argument starts with a digit or #.

       For example, suppose that procedure a was invoked from top-level, and that it called b, and that b called c.  Suppose that  c  invokes  the
       uplevel	command.   If  level  is 1 or #2  or omitted, then the command will be executed in the variable context of b.  If level is 2 or #1
       then the command will be executed in the variable context of a.	If level is 3 or #0 then the command will be executed at  top-level  (only
       global variables will be visible).

       The  uplevel  command  causes the invoking procedure to disappear from the procedure calling stack while the command is being executed.	In
       the above example, suppose c invokes the command
	      uplevel 1 {set x 43; d}
       where d is another Tcl procedure.  The set command will modify the variable x in b's context, and d will execute at level 3, as	if  called
       from b.	If it in turn executes the command
	      uplevel {set x 42}
       then  the  set  command	will modify the same variable x in b's context:  the procedure c does not appear to be on the call stack when d is
       executing.  The info level command may be used to obtain the level of the current procedure.

       Uplevel makes it possible to implement new control constructs as Tcl procedures (for example, uplevel could be used to implement the  while
       construct as a Tcl procedure).

       The  namespace  eval and apply commands offer other ways (besides procedure calls) that the Tcl naming context can change.  They add a call
       frame to the stack to represent the namespace context.  This means each namespace eval command counts as another call level for uplevel and
       upvar  commands.  For example, info level 1 will return a list describing a command that is either the outermost procedure call or the out-
       ermost namespace eval command.  Also, uplevel #0 evaluates a script at top-level in the outermost namespace (the global namespace).

EXAMPLE

       As stated above, the uplevel command is useful for creating new control constructs.  This example shows how (without error handling) it can
       be used to create a do command that is the counterpart of while except for always performing the test after running the loop body:
	      proc do {body while condition} {
		  if {$while ne "while"} {
		      error "required word missing"
		  }
		  set conditionCmd [list expr $condition]
		  while {1} {
		      uplevel 1 $body
		      if {![uplevel 1 $conditionCmd]} {
			  break
		      }
		  }
	      }

SEE ALSO

       apply(n), namespace(n), upvar(n)

KEYWORDS

       context, level, namespace, stack frame, variables

Tcl																	uplevel(n)