moose::cookbook::roles::recipe3(3) [osx man page]

Moose::Cookbook::Roles::Recipe3(3)			User Contributed Perl Documentation			Moose::Cookbook::Roles::Recipe3(3)

NAME

       Moose::Cookbook::Roles::Recipe3 - Applying a role to an object instance

VERSION

       version 2.0205

SYNOPSIS

	 package MyApp::Role::Job::Manager;

	 use List::Util qw( first );

	 use Moose::Role;

	 has 'employees' => (
	     is  => 'rw',
	     isa => 'ArrayRef[Employee]',
	 );

	 sub assign_work {
	     my $self = shift;
	     my $work = shift;

	     my $employee = first { !$_->has_work } @{ $self->employees };

	     die 'All my employees have work to do!' unless $employee;

	     $employee->work($work);
	 }

	 package main;

	 my $lisa = Employee->new( name => 'Lisa' );
	 MyApp::Role::Job::Manager->meta->apply($lisa);

	 my $homer = Employee->new( name => 'Homer' );
	 my $bart  = Employee->new( name => 'Bart' );
	 my $marge = Employee->new( name => 'Marge' );

	 $lisa->employees( [ $homer, $bart, $marge ] );
	 $lisa->assign_work('mow the lawn');

DESCRIPTION

       In this recipe, we show how a role can be applied to an object. In this specific case, we are giving an employee managerial
       responsibilities.

       Applying a role to an object is simple. The Moose::Meta::Role object provides an "apply" method. This method will do the right thing when
       given an object instance.

	 MyApp::Role::Job::Manager->meta->apply($lisa);

       We could also use the "apply_all_roles" function from Moose::Util.

	 apply_all_roles( $person, MyApp::Role::Job::Manager->meta );

       The main advantage of using "apply_all_roles" is that it can be used to apply more than one role at a time.

       We could also pass parameters to the role we're applying:

	 MyApp::Role::Job::Manager->meta->apply(
	     $lisa,
	     -alias => { assign_work => 'get_off_your_lazy_behind' },
	 );

       We saw examples of how method exclusion and alias working in roles recipe 2.

CONCLUSION

       Applying a role to an object instance is a useful tool for adding behavior to existing objects. In our example, it is effective used to
       model a promotion.

       It can also be useful as a sort of controlled monkey-patching for existing code, particularly non-Moose code. For example, you could create
       a debugging role and apply it to an object at runtime.

AUTHOR

       Stevan Little <stevan@iinteractive.com>

COPYRIGHT AND LICENSE

       This software is copyright (c) 2011 by Infinity Interactive, Inc..

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.12.5							    2011-09-06					Moose::Cookbook::Roles::Recipe3(3)

Check Out this Related Man Page

Moose::Cookbook::Meta::Recipe5(3)			User Contributed Perl Documentation			 Moose::Cookbook::Meta::Recipe5(3)

NAME

       Moose::Cookbook::Meta::Recipe5 - The "table" attribute as a metaclass trait

VERSION

       version 2.0205

SYNOPSIS

	 package MyApp::Meta::Class::Trait::HasTable;
	 use Moose::Role;

	 has table => (
	     is  => 'rw',
	     isa => 'Str',
	 );

	 package Moose::Meta::Class::Custom::Trait::HasTable;
	 sub register_implementation { 'MyApp::Meta::Class::Trait::HasTable' }

	 package MyApp::User;
	 use Moose -traits => 'HasTable';

	 __PACKAGE__->meta->table('User');

DESCRIPTION

       This recipe takes the metaclass table attribute from Moose::Cookbook::Meta::Recipe4 and implements it as a metaclass trait. Traits are just
       roles, as we saw in Moose::Cookbook::Meta::Recipe3.

       The advantage of using traits is that it's easy to combine multiple traits, whereas combining multiple metaclass subclasses requires
       creating yet another subclass. With traits, Moose takes care of applying them to your metaclass.

   Using this Metaclass Trait in Practice
       Once this trait has been applied to a metaclass, it looks exactly like the example we saw in Moose::Cookbook::Meta::Recipe4:

	 my $table = MyApp::User->meta->table;

	 # the safe version
	 $table = MyApp::User->meta->table
	     if MyApp::User->meta->meta->can('does')
		and MyApp::User->meta->meta->does('MyApp::Meta::Class');

       The safe version is a little complicated. We have to check that the metaclass object's metaclass has a "does" method, in which case we can
       ask if the the metaclass does a given role.

       It's simpler to just write:

	 $table = MyApp::User->meta->table
	     if MyApp::User->meta->can('table');

       In theory, this is a little less correct, since the metaclass might be getting its "table" method from a different role. In practice, you
       are unlikely to encounter this sort of problem.

SEE ALSO

       Moose::Cookbook::Meta::Recipe3 - Labels implemented via attribute traits

       Moose::Cookbook::Meta::Recipe4 - Adding a "table" attribute to the metaclass

AUTHOR

       Stevan Little <stevan@iinteractive.com>

COPYRIGHT AND LICENSE

       This software is copyright (c) 2011 by Infinity Interactive, Inc..

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.12.5							    2011-09-06					 Moose::Cookbook::Meta::Recipe5(3)

Linux and UNIX Man Pages

moose::cookbook::roles::recipe3(3) [osx man page]

Check Out this Related Man Page

Featured Tech Videos