moose::cookbook::roles::applicationtoinstance(3) [osx man page]

Moose::Cookbook::Roles::ApplicationToInstance(3)	User Contributed Perl Documentation	  Moose::Cookbook::Roles::ApplicationToInstance(3)

NAME

       Moose::Cookbook::Roles::ApplicationToInstance - Applying a role to an object instance

VERSION

       version 2.0604

SYNOPSIS

	 package MyApp::Role::Job::Manager;

	 use List::Util qw( first );

	 use Moose::Role;

	 has 'employees' => (
	     is  => 'rw',
	     isa => 'ArrayRef[Employee]',
	 );

	 sub assign_work {
	     my $self = shift;
	     my $work = shift;

	     my $employee = first { !$_->has_work } @{ $self->employees };

	     die 'All my employees have work to do!' unless $employee;

	     $employee->work($work);
	 }

	 package main;

	 my $lisa = Employee->new( name => 'Lisa' );
	 MyApp::Role::Job::Manager->meta->apply($lisa);

	 my $homer = Employee->new( name => 'Homer' );
	 my $bart  = Employee->new( name => 'Bart' );
	 my $marge = Employee->new( name => 'Marge' );

	 $lisa->employees( [ $homer, $bart, $marge ] );
	 $lisa->assign_work('mow the lawn');

DESCRIPTION

       In this recipe, we show how a role can be applied to an object. In this specific case, we are giving an employee managerial
       responsibilities.

       Applying a role to an object is simple. The Moose::Meta::Role object provides an "apply" method. This method will do the right thing when
       given an object instance.

	 MyApp::Role::Job::Manager->meta->apply($lisa);

       We could also use the "apply_all_roles" function from Moose::Util.

	 apply_all_roles( $person, MyApp::Role::Job::Manager->meta );

       The main advantage of using "apply_all_roles" is that it can be used to apply more than one role at a time.

       We could also pass parameters to the role we're applying:

	 MyApp::Role::Job::Manager->meta->apply(
	     $lisa,
	     -alias => { assign_work => 'get_off_your_lazy_behind' },
	 );

       We saw examples of how method exclusion and alias working in Moose::Cookbook::Roles::Restartable_AdvancedComposition.

CONCLUSION

       Applying a role to an object instance is a useful tool for adding behavior to existing objects. In our example, it is effective used to
       model a promotion.

       It can also be useful as a sort of controlled monkey-patching for existing code, particularly non-Moose code. For example, you could create
       a debugging role and apply it to an object at runtime.

AUTHOR

       Moose is maintained by the Moose Cabal, along with the help of many contributors. See "CABAL" in Moose and "CONTRIBUTORS" in Moose for
       details.

COPYRIGHT AND LICENSE

       This software is copyright (c) 2012 by Infinity Interactive, Inc..

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.16.2							    2012-09-19			  Moose::Cookbook::Roles::ApplicationToInstance(3)

Moose::Util::MetaRole(3)				User Contributed Perl Documentation				  Moose::Util::MetaRole(3)

NAME

       Moose::Util::MetaRole - Apply roles to any metaclass, as well as the object base class

VERSION

       version 2.0604

SYNOPSIS

	 package MyApp::Moose;

	 use Moose ();
	 use Moose::Exporter;
	 use Moose::Util::MetaRole;

	 use MyApp::Role::Meta::Class;
	 use MyApp::Role::Meta::Method::Constructor;
	 use MyApp::Role::Object;

	 Moose::Exporter->setup_import_methods( also => 'Moose' );

	 sub init_meta {
	     shift;
	     my %args = @_;

	     Moose->init_meta(%args);

	     Moose::Util::MetaRole::apply_metaroles(
		 for		 => $args{for_class},
		 class_metaroles => {
		     class => => ['MyApp::Role::Meta::Class'],
		     constructor => ['MyApp::Role::Meta::Method::Constructor'],
		 },
	     );

	     Moose::Util::MetaRole::apply_base_class_roles(
		 for   => $args{for_class},
		 roles => ['MyApp::Role::Object'],
	     );

	     return $args{for_class}->meta();
	 }

DESCRIPTION

       This utility module is designed to help authors of Moose extensions write extensions that are able to cooperate with other Moose
       extensions. To do this, you must write your extensions as roles, which can then be dynamically applied to the caller's metaclasses.

       This module makes sure to preserve any existing superclasses and roles already set for the meta objects, which means that any number of
       extensions can apply roles in any order.

USAGE

       The easiest way to use this module is through Moose::Exporter, which can generate the appropriate "init_meta" method for you, and make sure
       it is called when imported.

FUNCTIONS

       This module provides two functions.

   apply_metaroles( ... )
       This function will apply roles to one or more metaclasses for the specified class. It will return a new metaclass object for the class or
       role passed in the "for" parameter.

       It accepts the following parameters:

       o   for => $name

	   This specifies the class or for which to alter the meta classes. This can be a package name, or an appropriate meta-object (a
	   Moose::Meta::Class or Moose::Meta::Role).

       o   class_metaroles => \%roles

	   This is a hash reference specifying which metaroles will be applied to the class metaclass and its contained metaclasses and helper
	   classes.

	   Each key should in turn point to an array reference of role names.

	   It accepts the following keys:

	   class
	   attribute
	   method
	   wrapped_method
	   instance
	   constructor
	   destructor
	   error
       o   role_metaroles => \%roles

	   This is a hash reference specifying which metaroles will be applied to the role metaclass and its contained metaclasses and helper
	   classes.

	   It accepts the following keys:

	   role
	   attribute
	   method
	   required_method
	   conflicting_method
	   application_to_class
	   application_to_role
	   application_to_instance
	   application_role_summation
	   applied_attribute

   apply_base_class_roles( for => $class, roles => @roles )
       This function will apply the specified roles to the object's base class.

BUGS

       See "BUGS" in Moose for details on reporting bugs.

AUTHOR

       Moose is maintained by the Moose Cabal, along with the help of many contributors. See "CABAL" in Moose and "CONTRIBUTORS" in Moose for
       details.

COPYRIGHT AND LICENSE

       This software is copyright (c) 2012 by Infinity Interactive, Inc..

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.16.2							    2012-09-19						  Moose::Util::MetaRole(3)