moose::cookbook::meta::table_metaclasstrait(3) [osx man page]

Moose::Cookbook::Meta::Table_MetaclassTrait(3)		User Contributed Perl Documentation	    Moose::Cookbook::Meta::Table_MetaclassTrait(3)

NAME

       Moose::Cookbook::Meta::Table_MetaclassTrait - Adding a "table" attribute as a metaclass trait

VERSION

       version 2.0604

SYNOPSIS

	 # in lib/MyApp/Meta/Class/Trait/HasTable.pm
	 package MyApp::Meta::Class::Trait::HasTable;
	 use Moose::Role;
	 Moose::Util::meta_class_alias('HasTable');

	 has table => (
	     is  => 'rw',
	     isa => 'Str',
	 );

	 # in lib/MyApp/User.pm
	 package MyApp::User;
	 use Moose -traits => 'HasTable';

	 __PACKAGE__->meta->table('User');

DESCRIPTION

       In this recipe, we'll create a class metaclass trait which has a "table" attribute. This trait is for classes associated with a DBMS table,
       as one might do for an ORM.

       In this example, the table name is just a string, but in a real ORM the table might be an object describing the table.

THE METACLASS TRAIT

       This really is as simple as the recipe "SYNOPSIS" shows. The trick is getting your classes to use this metaclass, and providing some sort
       of sugar for declaring the table. This is covered in Moose::Cookbook::Extending::Debugging_BaseClassRole, which shows how to make a module
       like "Moose.pm" itself, with sugar like "has_table()".

   Using this Metaclass Trait in Practice
       Accessing this new "table" attribute is quite simple. Given a class named "MyApp::User", we could simply write the following:

	 my $table = MyApp::User->meta->table;

       As long as "MyApp::User" has arranged to apply the "MyApp::Meta::Class::Trait::HasTable" to its metaclass, this method call just works. If
       we want to be more careful, we can check that the class metaclass object has a "table" method:

	 $table = MyApp::User->meta->table
	     if MyApp::User->meta->can('table');

       In theory, this is not entirely correct, since the metaclass might be getting its "table" method from a different trait. In practice, you
       are unlikely to encounter this sort of problem.

RECIPE CAVEAT

       This recipe doesn't work when you paste it all into a single file. This is because the "use Moose -traits => 'HasTable';" line ends up
       being executed before the "table" attribute is defined.

       When the two packages are separate files, this just works.

SEE ALSO

       Moose::Cookbook::Meta::Labeled_AttributeTrait - Labels implemented via attribute traits

AUTHOR

       Moose is maintained by the Moose Cabal, along with the help of many contributors. See "CABAL" in Moose and "CONTRIBUTORS" in Moose for
       details.

COPYRIGHT AND LICENSE

       This software is copyright (c) 2012 by Infinity Interactive, Inc..

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.16.2							    2012-09-19			    Moose::Cookbook::Meta::Table_MetaclassTrait(3)

Check Out this Related Man Page

Moose::Cookbook::Extending::Mooseish_MooseSugar(3)	User Contributed Perl Documentation	Moose::Cookbook::Extending::Mooseish_MooseSugar(3)

NAME

       Moose::Cookbook::Extending::Mooseish_MooseSugar - Acting like Moose.pm and providing sugar Moose-style

VERSION

       version 2.0604

SYNOPSIS

	 package MyApp::Mooseish;

	 use Moose::Exporter;

	 Moose::Exporter->setup_import_methods(
	     with_meta	     => ['has_table'],
	     class_metaroles => {
		 class => ['MyApp::Meta::Class::Trait::HasTable'],
	     },
	 );

	 sub has_table {
	     my $meta = shift;
	     $meta->table(shift);
	 }

	 package MyApp::Meta::Class::Trait::HasTable;
	 use Moose::Role;

	 has table => (
	     is  => 'rw',
	     isa => 'Str',
	 );

DESCRIPTION

       This recipe expands on the use of Moose::Exporter we saw in Moose::Cookbook::Extending::ExtensionOverview and the class metaclass trait we
       saw in Moose::Cookbook::Meta::Table_MetaclassTrait. In this example we provide our own metaclass trait, and we also export a "has_table"
       sugar function.

       The "with_meta" parameter specifies a list of functions that should be wrapped before exporting. The wrapper simply ensures that the
       importing package's appropriate metaclass object is the first argument to the function, so we can do "my $meta = shift;".

       See the Moose::Exporter docs for more details on its API.

USING MyApp::Mooseish
       The purpose of all this code is to provide a Moose-like interface. Here's what it would look like in actual use:

	 package MyApp::User;

	 use namespace::autoclean;

	 use Moose;
	 use MyApp::Mooseish;

	 has_table 'User';

	 has 'username' => ( is => 'ro' );
	 has 'password' => ( is => 'ro' );

	 sub login { ... }

CONCLUSION

       Providing sugar functions can make your extension look much more Moose-ish. See Fey::ORM for a more extensive example.

AUTHOR

       Moose is maintained by the Moose Cabal, along with the help of many contributors. See "CABAL" in Moose and "CONTRIBUTORS" in Moose for
       details.

COPYRIGHT AND LICENSE

       This software is copyright (c) 2012 by Infinity Interactive, Inc..

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.16.2							    2012-09-19			Moose::Cookbook::Extending::Mooseish_MooseSugar(3)

Linux and UNIX Man Pages

moose::cookbook::meta::table_metaclasstrait(3) [osx man page]

Check Out this Related Man Page