moose::cookbook::extending::recipe4(3) [osx man page]

Moose::Cookbook::Extending::Recipe4(3)			User Contributed Perl Documentation		    Moose::Cookbook::Extending::Recipe4(3)

NAME

       Moose::Cookbook::Extending::Recipe4 - Acting like Moose.pm and providing sugar Moose-style

VERSION

       version 2.0205

SYNOPSIS

	 package MyApp::Mooseish;

	 use Moose ();
	 use Moose::Exporter;

	 Moose::Exporter->setup_import_methods(
	     with_meta => ['has_table'],
	     also      => 'Moose',
	 );

	 sub init_meta {
	     shift;
	     return Moose->init_meta( @_, metaclass => 'MyApp::Meta::Class' );
	 }

	 sub has_table {
	     my $meta = shift;
	     $meta->table(shift);
	 }

	 package MyApp::Meta::Class;
	 use Moose;

	 extends 'Moose::Meta::Class';

	 has 'table' => ( is => 'rw' );

DESCRIPTION

       This recipe expands on the use of Moose::Exporter we saw in Moose::Cookbook::Extending::Recipe1. Instead of providing our own object base
       class, we provide our own metaclass class, and we also export a "has_table" sugar function.

       Given the above code, you can now replace all instances of "use Moose" with "use MyApp::Mooseish". Similarly, "no Moose" is now replaced
       with "no MyApp::Mooseish".

       The "with_meta" parameter specifies a list of functions that should be wrapped before exporting. The wrapper simply ensures that the
       importing package name is the first argument to the function, so we can do "my $caller = shift;".

       See the Moose::Exporter docs for more details on its API.

USING MyApp::Mooseish
       The purpose of all this code is to provide a Moose-like interface. Here's what it would look like in actual use:

	 package MyApp::User;

	 use MyApp::Mooseish;

	 has_table 'User';

	 has 'username' => ( is => 'ro' );
	 has 'password' => ( is => 'ro' );

	 sub login { ... }

	 no MyApp::Mooseish;

       All of the normal Moose sugar ("has()", "with()", etc) is available when you "use MyApp::Mooseish".

CONCLUSION

       Providing sugar functions can make your extension look much more Moose-ish. See Fey::ORM for a more extensive example.

AUTHOR

       Stevan Little <stevan@iinteractive.com>

COPYRIGHT AND LICENSE

       This software is copyright (c) 2011 by Infinity Interactive, Inc..

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.12.5							    2011-09-06				    Moose::Cookbook::Extending::Recipe4(3)

Moose::Cookbook::Extending::Recipe3(3)			User Contributed Perl Documentation		    Moose::Cookbook::Extending::Recipe3(3)

NAME

       Moose::Cookbook::Extending::Recipe3 - Providing an alternate base object class

VERSION

       version 2.0205

SYNOPSIS

	 package MyApp::Base;
	 use Moose;

	 extends 'Moose::Object';

	 before 'new' => sub { warn "Making a new " . $_[0] };

	 no Moose;

	 package MyApp::UseMyBase;
	 use Moose ();
	 use Moose::Exporter;

	 Moose::Exporter->setup_import_methods( also => 'Moose' );

	 sub init_meta {
	     shift;
	     return Moose->init_meta( @_, base_class => 'MyApp::Base' );
	 }

DESCRIPTION

       A common extension is to provide an alternate base class. One way to do that is to make a "MyApp::base" and add "extends 'MyApp::Base'" to
       every class in your application. That's pretty tedious. Instead, you can create a Moose-alike module that sets the base object class to
       "MyApp::Base" for you.

       Then, instead of writing "use Moose" you can write "use MyApp::UseMyBase".

       In this particular example, our base class issues some debugging output every time a new object is created, but you can think of some more
       interesting things to do with your own base class.

       This uses the magic of Moose::Exporter. When we call "Moose::Exporter->setup_import_methods( also => 'Moose' )" it builds "import" and
       "unimport" methods for you. The "also => 'Moose'" bit says that we want to export everything that Moose does.

       The "import" method that gets created will call our "init_meta" method, passing it "for_caller => $caller" as its arguments. The $caller is
       set to the class that actually imported us in the first place.

       See the Moose::Exporter docs for more details on its API.

USING MyApp::UseMyBase
       To actually use our new base class, we simply use "MyApp::UseMyBase" instead of "Moose". We get all the Moose sugar plus our new base
       class.

	 package Foo;

	 use MyApp::UseMyBase;

	 has 'size' => ( is => 'rw' );

	 no MyApp::UseMyBase;

CONCLUSION

       This is an awful lot of magic for a simple base class. You will often want to combine a metaclass trait with a base class extension, and
       that's when this technique is useful.

AUTHOR

       Stevan Little <stevan@iinteractive.com>

COPYRIGHT AND LICENSE

       This software is copyright (c) 2011 by Infinity Interactive, Inc..

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.12.5							    2011-09-06				    Moose::Cookbook::Extending::Recipe3(3)