One can do that, but if you do the output from the input line:

Code:

BUC2  : 1203100,BUC2 COUNT : 318678,BUC2 GIVEN : 3493491.59

becomes:

Code:

12031003186783493491.59

instead of:

Code:

1203100 318678 3493491.59

One could also get rid of the space after the colon in the BRE:

Code:

sed 's/,\{0,1\}[^,]*://g' file

and that would make the output from the above input line be:

Code:

 1203100 318678 3493491.59

which is almost what is wanted, but has an extraneous leading space on every output line.

One could also try:

Code:

sed 's/[^,]*: \([0-9.]*\),\{0,1\}/\1 /g' file

and that looks like the desired output to the naked eye, but has an extraneous trailing space on every output line.

The following seems to do what is wanted with a single sed substitution command:

Code:

sed 's/[^,]*: \([0-9.]*\),\{0,1\}[^ ]*\( \{0,1\}\)/\1\2/g' file

but it is not something that I would suggest for someone who is just learning how to use sed and learning how to write sed BREs (unless I was trying to show an example of the sed-specific extensions to standard BREs and the use of back references in replacement strings).

Note that all of the examples above work with standards-conforming versions of sed, but might need an added option on the command line to make it work with GNU sed. For example, the last example above, when using GNU sed, probably needs to be invoked with:

Code:

sed --posix 's/[^,]*: \([0-9.]*\),\{0,1\}[^ ]*\( \{0,1\}\)/\1\2/g' file