sort data in different columns

mogabr · #1 (**permalink**) 08-02-2008

Hello all:

i have list with the following format
Id Name Iid Value
0x4440001 customerCode 44077
0x11d2a PrimaryAddress 57.217.41.201
0x129fa Model_Handle 0x11322800
0x4440000 usid fi00bxtaa4
0x4440008 customerName Zurich

while i needed to be in the next format
customerCode PrimaryAddress Model_Handle usid
44077 55.217.41.201 0x11322800 fi00bxtaa4

how to do so ?

regards

cfajohnson · #2 (**permalink**) 08-02-2008

Code:

awk ' NR == 1 { next }
{
 name[NR-1] = $2
 value[NR-1] = $3
}
END {
 while ( ++n < NR - 1 ) printf "%s ", name[n]
 print ""
 while ( ++v < NR - 1 ) printf "%s ", value[v]
 print ""
}' "$FILE"

mogabr · #3 (**permalink**) 08-03-2008

Quote:

Originally Posted by cfajohnson

Code:

awk ' NR == 1 { next }
{
 name[NR-1] = $2
 value[NR-1] = $3
}
END {
 while ( ++n < NR - 1 ) printf "%s ", name[n]
 print ""
 while ( ++v < NR - 1 ) printf "%s ", value[v]
 print ""
}' "$FILE"

hello

but the input data will be repeated in the file in that way
Id Name Iid Value
0x4440001 customerCode 44077
0x11d2a PrimaryAddress 57.217.41.201
0x129fa Model_Handle 0x11322800
0x4440000 usid fi00bxtaa4
0x4440008 customerName Zurich
Id Name Iid Value
0x4440001 customerCode 44044
0x11d2a PrimaryAddress 57.210.40.20
0x129fa Model_Handle 0x11326500
0x4440000 usid fi00bxtbb0
0x4440008 customerName Zurich

and so on ...

aigles · #4 (**permalink**) 08-03-2008

Try and adapt the following script.
The variable NamesList contains all the required names in output.

Code:

awk -v NamesList="customerCode,PrimaryAddress,Model_Handle,usid" \
'

function output_datas(    i, out) {
   if (Valid) {
      for (i=1; i<=NamesCount; i++) {
         out = (out ? out OFS : "") Values[i];
      }
      print out;
   }
}

function reset_datas(    i) {
   Valid = "";
   for (i=1; i<=NamesCount; i++)
      Values[i] = "";
}

BEGIN {
   NamesCount = split(NamesList, Names, ",");
   Header = "";
   for (i=1; i<=NamesCount; i++) {
      Indexes[tolower(Names[i])] = i;
      Header = (Header ? Header OFS : "") Names[i];
   }
   print Header;
}

/^Id/ {
   output_datas();
   reset_datas();
   next;
}

{
   name = tolower($2);
   value = $3;
   if (name in Indexes)  {
      Values[Indexes[name]] = value;
      Valid++;
   }
}

END {
   output_datas();
}
' mogarb.dat

Input datas (mogarb.dat)

Code:

Id Name Iid Value
0x4440001 customerCode 44077
0x11d2a PrimaryAddress 57.217.41.201
0x129fa Model_Handle 0x11322800
0x4440000 usid fi00bxtaa4
0x4440008 customerName Zurich
Id Name Iid Value
0x4440001 customerCode 44044
0x11d2a PrimaryAddress 57.210.40.20
0x129fa Model_Handle 0x11326500
0x4440000 usid fi00bxtbb0
0x4440008 customerName Zurich

Output

Code:

customerCode PrimaryAddress Model_Handle usid
44077 57.217.41.201 0x11322800 fi00bxtaa4
44044 57.210.40.20 0x11326500 fi00bxtbb0

Jean-Pierre.

radoulov · #5 (**permalink**) 08-03-2008

I'm not sure if you want to sort or to change the format only:
(use nawk or /usr/xpg4/bin/awk on Solaris)

Code:

awk 'BEGIN { 
  print "customerCode PrimaryAddress Model_Handle usid" 
  }
c && c < 5 { 
  v = v ? v FS $NF : $NF 
  } 
++c == 6 { 
  print v
  v = c = "" 
  }' filename

mogabr · #6 (**permalink**) 08-03-2008

Quote:

Originally Posted by radoulov

I'm not sure if you want to sort or to change the format only:
(use nawk or /usr/xpg4/bin/awk on Solaris)

Code:

awk 'BEGIN { 
  print "customerCode PrimaryAddress Model_Handle usid" 
  }
c && c < 5 { 
  v = v ? v FS $NF : $NF 
  } 
++c == 6 { 
  print v
  v = c = "" 
  }' filename

getting the same error
awk: syntax error near line 4
awk: bailing out near line 4

mogabr · #7 (**permalink**) 08-03-2008

Quote:

Originally Posted by aigles

Try and adapt the following script.
The variable NamesList contains all the required names in output.

Code:

awk -v NamesList="customerCode,PrimaryAddress,Model_Handle,usid" \
'
 
function output_datas(    i, out) {
   if (Valid) {
      for (i=1; i<=NamesCount; i++) {
         out = (out ? out OFS : "") Values[i];
      }
      print out;
   }
}
 
function reset_datas(    i) {
   Valid = "";
   for (i=1; i<=NamesCount; i++)
      Values[i] = "";
}
 
BEGIN {
   NamesCount = split(NamesList, Names, ",");
   Header = "";
   for (i=1; i<=NamesCount; i++) {
      Indexes[tolower(Names[i])] = i;
      Header = (Header ? Header OFS : "") Names[i];
   }
   print Header;
}
 
/^Id/ {
   output_datas();
   reset_datas();
   next;
}
 
{
   name = tolower($2);
   value = $3;
   if (name in Indexes)  {
      Values[Indexes[name]] = value;
      Valid++;
   }
}
 
END {
   output_datas();
}
' mogarb.dat

Input datas (mogarb.dat)

Code:

Id Name Iid Value
0x4440001 customerCode 44077
0x11d2a PrimaryAddress 57.217.41.201
0x129fa Model_Handle 0x11322800
0x4440000 usid fi00bxtaa4
0x4440008 customerName Zurich
Id Name Iid Value
0x4440001 customerCode 44044
0x11d2a PrimaryAddress 57.210.40.20
0x129fa Model_Handle 0x11326500
0x4440000 usid fi00bxtbb0
0x4440008 customerName Zurich

Output

Code:

customerCode PrimaryAddress Model_Handle usid
44077 57.217.41.201 0x11322800 fi00bxtaa4
44044 57.210.40.20 0x11326500 fi00bxtbb0

Jean-Pierre.

Hello Jean

when run script getting error
awk: syntax error near line 1
awk: bailing out near line 1
please advice

More UNIX and Linux Forum Topics You Might Find Helpful
Thread	Thread Starter	Forum	Replies	Last Post
Remove lines, Sorted with Time based columns using AWK & SORT	karthikn7974	Shell Programming and Scripting	1	05-09-2008 11:04 PM
sort columns by field	kamel.seg	Shell Programming and Scripting	4	02-20-2008 06:50 AM
add columns from file to another and sort	kamel.seg	Shell Programming and Scripting	12	12-12-2007 02:39 PM
Help needed to sort multiple columns in one file	ahjiefreak	UNIX for Dummies Questions & Answers	1	12-07-2007 05:50 AM
Sort by Columns	murbina	UNIX for Dummies Questions & Answers	1	05-10-2004 02:21 PM

Thread Tools	Search this Thread
Show Printable Version Email this Page	Search this Thread: Advanced Search
Display Modes	Rate This Thread
Switch to Linear Mode Hybrid Mode Switch to Threaded Mode	Rate This Thread: