Another transposing issue - Shell Programming and Scripting

stevesmith · #1 (**permalink**) 09-15-2006

Hello

I need to sort a file with data such as so it breaks on column 1 and all the data in column 2 is sorted into rows with a unique column 1:
1 5
1 6
1 7
2 3
2 4
3 7
3 0
3 9

So it comes out as:
1 5 6 7
2 3 4
3 7 0 9

I've tried many iterations of nawk but can't get it working!!!

Thanks in advance!

vgersh99 · #2 (**permalink**) 09-15-2006

what have you tried so far?

anbu23 · #3 (**permalink**) 09-15-2006

Code:

awk '
{
   if ( arr[$1] == "" )
        arr[$1]=$1 " " $2
   else
        arr[$1]=arr[$1] " " $2
}
END{
   for( key in arr)
        print arr[key]
}
' file

vgersh99 · #4 (**permalink**) 09-15-2006

Quote:

Originally Posted by anbu23

Code:

awk '
{
   if ( arr[$1] == "" )
        arr[$1]=$1 " " $2
   else
        arr[$1]=arr[$1] " " $2
}
END{
   for( key in arr)
        print arr[key]
}
' file

and how does this accomplish what the OP wants?

vgersh99 · #5 (**permalink**) 09-15-2006

here's one way of sorting by both rows [by $1] and columns within the rows:

nawk -f steve.awk steve.txt | sort -k 1n,1

steve.awk:

Code:

function isort(A,n,     i,j,t) {
    for (i = 2; i <= n; i++)
        for (j = i; j > 1 && A[j-1] > A[j]; j--) {
              # swap A[j-1] and A[j]
              t = A[j-1]; A[j-1] = A[j]; A[j] = t
        }
}

{
  arr[$1] = ($1 in arr) ? arr[$1] OFS $2 : $2
}

END {
  for ( i in arr ) {
    n=split(arr[i], tmpA, OFS)
    isort(tmpA, n)
    printf("%s%s", i, OFS )
    for(j=1; j <= n; j++)
       printf("%s%s", tmpA[j], (j==n) ? "\n" : OFS)
  }
}

anbu23 · #6 (**permalink**) 09-15-2006

Quote:

Originally Posted by anbu23
Code:
awk '
{
if ( arr[$1] == "" )
arr[$1]=$1 " " $2
else
arr[$1]=arr[$1] " " $2
}
END{
for( key in arr)
print arr[key]
}
' file

and how does this accomplish what the OP wants?

Did you try running this code?
This code will give what the output he has given.
if he wants second column to be sorted
sort -kn1 -kn2 file | awk ' ...'

vgersh99 · #7 (**permalink**) 09-15-2006

well..... even assuming fixing the 'sort' options - these syntax is illegal on Sun/Solaris....
Also assuming the OP's sample input file [steve.txt]...

Code:

$ sort -n -k 1,1 -k 2,2 steve.txt | nawk -f steve1.awk 
2 3 4
3 0 7 9
1 5 6 7

are you seeing different results?

More UNIX and Linux Forum Topics You Might Find Helpful
Thread	Thread Starter	Forum	Replies	Last Post
More than transposing!	bulash	UNIX Desktop for Dummies Questions & Answers	3	04-11-2008 02:20 PM
Transposing string	unibboy	Shell Programming and Scripting	3	02-13-2008 02:12 PM
Major Awk problems (Searching, If statements, transposing etc.)	Blivo	Shell Programming and Scripting	2	09-05-2007 03:41 AM
file transposing	mskcc	Shell Programming and Scripting	24	08-04-2005 08:23 AM
transposing letters	myscsa2004	Shell Programming and Scripting	4	05-12-2004 07:11 AM

Thread Tools
Show Printable Version Email this Page
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode