using awk

cin2000 · #1 (**permalink**) 11-28-2005

Hi,
I have one file like below:
0744 111305 9.92 52008
1552 111305 1.70 52008
5345 111305 0.40 52008
1552 111305 1.58 52056

and other file like below:
1552 name2
0744 name3
5345 name4

I need to paste the "name" column in the second file to the fist file if there is any match on the fist column. I can't use paste command since first file will have duplicated ID on the first column.

This is what I'd like to show on the final file:
0744 name3 11305 9.92 52008
1552 name2 111305 1.70 52008
5345 name4 111305 0.40 52008
1552 name2111305 1.58 52056

Any help would be very appreciated!

cin2000 · #2 (**permalink**) 11-28-2005

Hi,
I am new to shell and awk.
Can anyone give me a hint where I should start with it?

Thanks!

vgersh99 · #3 (**permalink**) 11-28-2005

nawk -f cin.awk otherFile oneFile

with cin.awk being:

Code:

NR==FNR { arr[$1]=$2; next }
$1 in arr { $1 = $1 OFS arr[$1] }
1

cin2000 · #4 (**permalink**) 11-28-2005

Hi,
Thanks a lot! It worked.
I am wondering if you could explain with plain English because I like to know how I can modify the code for my program.

Thanks again!

vgersh99 · #5 (**permalink**) 11-28-2005

here's the code with embedded comments:

Quote:

Originally Posted by vgersh99

nawk -f cin.awk otherFile oneFile

with cin.awk being:

Code:

# 'NR == FNR' results in 'true' ONLY for the FIRST file passed to script
# do 'man nawk' to get a detailed description(s) on FNR and NR
# when 'FNR==NR' create an array 'arr' indexed by the value of FIRST field '$1'
# and assigned a value of the SECOND field '$2'. 'next' skips the rest of the
# script and goes to the next record/line
NR==FNR { arr[$1]=$2; next }


# we get here for the file(s) OTHER than the  FIRST file
# If the value of the FIRST field '$1' is in the array '$1' - execute the action
# within the curlies: suffix the value of the FIRST field '$1' with the value of
# OFS [OutputFieldSeparator] followed by the value found in the array 'arr'
# indexed by the value of the FIRST field '$1' 
$1 in arr { $1 = $1 OFS arr[$1] }


# this is a shorthand for '{print}' which prints the current record
1

Abhishek Ghose · #6 (**permalink**) 11-29-2005

There is command in UNIX which does a "join" on files using their columns (analogous to database table joins). The only condition being the fields on which join to be performed should be sorted.

Lets call the first file "file1" and the second file "file2".
Heres what you can do:

sort file1>sfile1;sort file2>sfile2;
join -a1 -o 1.1,1.2,1.3,1.4,2.2 sfile1 sfile2

Explanation:
-o lets you specify which columns you want to see in ur output. Columns belonging to the first file are denoted by 1 followed by a decimal point and the column number. Columns belonging to the second file are denoted by 2 followed by a decimal point and the column number. So here we trying to see all columns from the first file and the second column from the second file in the order specified.

The -a flag prints unpaired lines from file1.

Thread Tools	Search this Thread
Show Printable Version Email this Page	Search this Thread: Advanced Search
Display Modes	Rate This Thread
Switch to Linear Mode Hybrid Mode Switch to Threaded Mode	Rate This Thread:


	Powered by