awk removing data before or after a pattern


 
Thread Tools Search this Thread
Top Forums Shell Programming and Scripting awk removing data before or after a pattern
# 1  
Old 08-08-2010
awk removing data before or after a pattern

I have the following data:

01:00:00 29 10 20 41
01:20:00 18 6 34 42
01:40:00 28 5 24 43
02:00:01 11 7 8 74
02:20:01 19 15 12 54
02:40:01 1 4 0 95
03:00:01 1 3 0 96
03:20:01 0 0 0 99
03:40:01 1 2 0 97

First I want to remove all data after a certain pattern, Ie 03:00 sp this
should leave me with the following results

01:00:00 29 10 20 41
01:20:00 18 6 34 42
01:40:00 28 5 24 43
02:00:01 11 7 8 74
02:20:01 19 15 12 54
02:40:01 1 4 0 95
03:00:01 1 3 0 96


Secondly I would also like to know how to remove all before the pattern
so this should leave me with the following results.

03:00:01 1 3 0 96
03:20:01 0 0 0 99
03:40:01 1 2 0 97

Note: Both these statements not be run at the same time.

Thanks to all who answer.
# 2  
Old 08-08-2010
Removing after pattern:
Code:
awk '!p;/^03:00/{p=1}' file

Removing before pattern:
Code:
awk '/^03:00/{p=1}p' file

# 3  
Old 08-08-2010
This is one way to accomplish what you need; may not be the most efficient, but is easy to understand. It will do both 'drop before' and 'drop after' functions. I've set it up to match strings, not patterns, if you truly need to match patterns, use the match() function in awk rather than index().

Code:
#!/usr/bin/env ksh

# parms:        $1 -- before string; all records before matching this string are dropped
#                       If this is "none" then all records until the after string is matched are kept
#               $2 -- after string; all records after this string are dropped.

awk -v toss_before="${1:-none}" -v toss_after="$2" '
        BEGIN {
                if( toss_before == "none" )     # keep everything from the start
                        snarf = 1;
                else
                        snarf = 0;              # must wait until we see toss_before to start keeping data
        }

        {
                if( snarf ) 
                {
                        printf( "%s\n", $0 );           # print if snarfing 

                        if( toss_after && index( $0, toss_after ) )     # check to see if this has the end string
                                exit( 0 );
                }
                else                                    # not snarfing, see if this is the start string
                {
                        if( index( $0, toss_before ) )
                        {
                                printf( "%s\n", $0 );
                                snarf = 1;
                        }
                }
        }
'

# 4  
Old 08-08-2010
Quote:
Originally Posted by bartus11
Removing after pattern:
Code:
awk '!p;/^03:00/{p=1}' file

Removing before pattern:
Code:
awk '/^03:00/{p=1}p' file


Could you pls explain why it is working?? its seems interesting. I knw the basis of awk but how this printing is happening by assigning one variable ? is it due to some special variable like $_ in perl??
# 5  
Old 08-08-2010
Quote:
Originally Posted by gvj
Could you pls explain why it is working??
His script is taking advantage of the fact that if the action part of a pattern-action pair is missing, the action {print;} is assumed. Further, !p is the same as saying 'p == 0' in the pattern portion of the statement. The value of an undefined variable is either 0 or "" depending on how it is used. To write the script in 'long form' might make more sense to you:

Code:
awk ' 
BEGIN { p = 0;}
p == 0 { print; }       # pattern not matched; print  (!p;)
/^03:00/ { p = 1; }  # pattern is matched, stop printing (exit(0) would be more efficient)
' file

Similarly, printing everything after the pattern line:
Code:
BEGIN { p = 0;}
/^03:00/ { p = 1; }  # pattern is matched, allow printing
p != 0 { print; }       # p;  in the original script
' file

This User Gave Thanks to agama For This Post:
# 6  
Old 08-08-2010
Code:
sed -n '1,/03:00/p' file

Code:
sed -n '/03:00/,$p' file

# 7  
Old 08-09-2010
Code:
awk '$1<"03:00:00"' urfile

Code:
awk '$1>="03:00:00"' urfile

Login or Register to Ask a Question

Previous Thread | Next Thread

10 More Discussions You Might Find Interesting

1. Shell Programming and Scripting

awk to grab data in range then search for pattern

im using the following code to grab data, but after the data in the range im specifying has been grabbed, i want to count how many instances of a particular pattern is found? awk 'BEGIN{count=0} /parmlib.*RSP/,/seqfiles.*SSD/ {print; count++ } /103 error in ata file/ END { print count }'... (3 Replies)
Discussion started by: SkySmart
3 Replies

2. UNIX for Dummies Questions & Answers

Removing PATTERN from txt without removing lines and general text formatting

Hi Everybody! First post! Totally noobie. I'm using the terminal to read a poorly formatted book. The text file contains, in the middle of paragraphs, hyphenation to split words that are supposed to be on multiple pages. It looks ve -- ry much like this. I was hoping to use grep -v " -- "... (5 Replies)
Discussion started by: AxeHandle
5 Replies

3. Shell Programming and Scripting

Removing a pattern in a line

Dear team, I have a file curve.csv which is generated from oracle and each line has a comment associated with it, I want to get rid of this comment, can you please suggest me a command as how to do it Eg, cat curve.csv /*data for today curve*/ /*data for text1*/ this is the header /*data... (6 Replies)
Discussion started by: infyanurag
6 Replies

4. Shell Programming and Scripting

Removing files matching a pattern

I am on ubuntu 11.10 using bash scripts I want to remove all files matching a string pattern and I am using the following code find . -name "*$pattern*" -exec rm -f {} \;I have encountered a problem when $pattern is empty. In this case all my files in my current directory were deleted. This... (3 Replies)
Discussion started by: kristinu
3 Replies

5. Shell Programming and Scripting

how to get data from hex file using SED or AWK based on pattern sign

I have a binary (hex) file I need to parse to get some data which are encoded this way: .* b4 . . . 01 12 .* af .* 83 L1 x1 x2 xL 84 L2 y1 y2 yL By another words there is a stream of hexadecimal bytes (in my example separated by space for better readability). I need to get value stored in... (3 Replies)
Discussion started by: sameucho
3 Replies

6. Shell Programming and Scripting

Removing repeating lines from a data frame (AWK)

Hey Guys! I have written a code which combines lots of files into one big file(.csv). However, each of the original files had headers on the first line, and now that I've combined the files the headers are interspersed throughout the new combined data frame. For example, throughout the data... (21 Replies)
Discussion started by: gd9629
21 Replies

7. Shell Programming and Scripting

Removing data with pattern matching

I have the following: HH:MM:SS I want to use either % or # sign to remove :SS can somebody please provide me an example. I know how to do this in awk, but awk is too much overhead for something this simple since I will be doing this in a loop a lot of times. Thanks in advance to all... (2 Replies)
Discussion started by: BeefStu
2 Replies

8. Shell Programming and Scripting

SFTP to server, pulling data and removing the data

Hi all, I have the following script, but are not too sure about the syntax to complete the script. In essence, the script must connect to a SFTP server at a client site with username and password located in a file on my server. Then change to the appropriate directory. Pull the data to the... (1 Reply)
Discussion started by: codenjanod
1 Replies

9. Shell Programming and Scripting

Replacing or removing a long list of pattern by using awk or sed

Input: >abc|123456|def|EXIT| >abc|203456|def|EXIT2| >abc|234056|def|EXIT3| >abc|340056|def|EXIT4| >abc|456000|def|EXIT5| . . . Output: def|EXIT| def|EXIT2| def|EXIT3| def|EXIT4| def|EXIT5| . . My try code: (9 Replies)
Discussion started by: patrick87
9 Replies

10. Shell Programming and Scripting

removing a line containing a pattern in sed

i need to use sed to remove an entire line containing a pattern stored in a variable say $var1 this var1 will be a URL and will therefore contain slashes any help would be greatly appreciated (1 Reply)
Discussion started by: Fire_Storm
1 Replies
Login or Register to Ask a Question