Én vagyok a rendszergazda a nagy hálózat, HP / UX szerverek, a mintegy 100, ez egyre több mint 200, a következő 18 hónapon belül, részben az én vámokat kell megváltoztatni a root jelszót a gép, ha ezek a hó ... amely a fájdalom. Írtam egy szkriptet generál véletlenszerű jelszavakat meg és nyomtassa ki, hogy nem kell gondolni, és írjuk le a jelszavak biztonságos vezetése.

Igen, te kitaláltad a következő kérdés ... hogyan tudom átadni a jelszavakat egy szkriptet, amely megváltoztatja ezeket automatikusan minden gépen?

Én egy kicsit nagyon keresett, és talált egy válasz, hogy a GNU bináris várják, de nehézségei getting a bináris dolgozik a szerverek, meg én nem értem nem dolgozik valaki van valami ötleted?

Felhívjuk figyelmét, hogy a vállalati politika nem engedi meg, hogy használja a távoli kagyló, pszeudo root felhasználó és egyik sem lejáró számlák.

Köszi előre

- Paul

Ha a vállalat azt a biztonságot, akkor mutasd meg, hogy az egyetlen módja, hogy mit akarunk, a 3. fél fedezettségét.

VAGY

Lehet használni NIS root fiók - Így --
Még a normális root fiók, amely itt info a / etc / passwd (és árnyék). Ha a szerver néz NIS kép előtt, akkor lehetett volna egy NIS root fiók - egy jelszót minden szerverek (igen, hátránya, hogy túl!). Ha NIS volt elérhető, akkor tudni, hogy mi a kiszolgáló helyi root jelszót, hogy jelentkezzen be, vagy a su root.

Megváltoztatni a jelszavakat minden szerverek szükség néhány típusú léphetnek - az "ingyenes" termék nevezett cfengine amely jól működött (bár a honlapunkon elveszett 46 szerverek egy perc miatt a bug (ami állandó, de soha nem használta Ismét)). Egy másik módja az, ha van programozási ismeretek írni a saját.

Saját véleménye a 3. fél szoftvert. Láttam, hogy a munka és azt teszi, hogy könnyen kezelhető (ez a mix a Solaris és a HP szerverek). Azt hiszem, RSA Security teszi / értékesíti azt.

Azt találta, hogy ez a szkript, amely használja egy kicsit várni ezelőtt, még nem volt ideje mess vele mégis, talán ez segít neked kezdődött

#!/usr/local/bin/expect

if { $argc != 3 } {
    puts "Usage:"
    puts "$argv0 username oldpwd newpwd"
    exit
}

#set machine  [lindex $argv 0]
set username [lindex $argv 0]
set oldpwd   [lindex $argv 1]
set newpwd   [lindex $argv 2]
set completed_list " "

#-----------------------------------------
# All machines where set password on
#-----------------------------------------
set machine_list {
machine1
machine2
machine3
etc
etc
}


#----------------------------------------------------
# Ping machines to see which ones are available
#   ok machines in run_list
#----------------------------------------------------
foreach machine $machine_list {
    if { [ catch { exec ping -c 1 $machine  } ] == 0 } {
        lappend run_list $machine
    }
}


proc exclude_list {} {
    set count 0
    global machine_list run_list
    foreach machine $machine_list {
        incr count
        if { [ lsearch $run_list $machine ] < 0 } {
            puts "\t$count)\t$machine"
        }
    }    
    puts ""
}

proc include_list {} {
    puts "Will now try to change password on following machines:"
    set count 0
    global machine_list run_list
    foreach machine $run_list {
        incr count
            puts "\t$count)\t$machine"
    }
    puts ""
}

proc continue_chk {} {
    global run_list
    while {1} {
        include_list
        puts -nonewline "\nDo you want to continue or (m)odify list? (y/n/m): "
        gets stdin ans 
        if { 1 == [regexp {^y|Y$} $ans]  } {
            puts "yes"
            break
        } elseif { 1 == [regexp {^m|M$} $ans]  } {
            puts -nonewline "\n Enter number to remove: "
            gets stdin ans 
            set r_num [expr {$ans - 1}]
            puts $run_list
            set run_list [ lreplace $run_list $r_num $r_num ] 
        } else {
            puts "no"
            exit
        }
    }
}
    
puts "Failed to ping following machines:"
exclude_list

#puts "Will now try to change password on following machines:"
#include_list

continue_chk

foreach machine $run_list { 
    set change 0
    spawn telnet $machine
    while {1} {
        expect  { 
            timeout         break
            "\rlogin:"        { sleep 1
                              send "${username}\r" }
            "New password"  { send "${newpwd}\r" 
                              lappend completed_list $machine
                              set change 1 }
            "new password"  { send "${newpwd}\r" 
                             set change 1 }
            "Old password:" { send "${oldpwd}\r" }
            "Password:"     { send "${oldpwd}\r" }
            "\\\$"            { if {$change == 0} { 
                                  send "passwd\r" 
                                  set change 1 
                              } else {
                                  send "exit\r" }
                            }
            "changed"       { send "exit\r" }
            "closed"        { break }
        }
        sleep 1
    }
}
    
puts " "
puts "Password changed on following machines:"
foreach machine $completed_list {
    puts $machine
}

puts " "
puts "Password NOT changed on following machines:"
foreach machine $machine_list {
    if { [ lsearch $completed_list $machine ] < 0 } {
        puts $machine
    }
}
exit

El tudja szerezni "elvárják", és minden más, jól ismert ingyenes szoftver már összeállított futtatásához a HP-UX. Lát ez felad a részletekért.