À propos de nature associative de awk tableaux, je suis encore confus, pas encore en mesure de comprendre la façon dont l'élément de tableau peut être consulté sur la base d'un string, j'ai eu un exemple à gawk manuel associatif pour illustrer la nature des tableaux awk, il est ici:
Code

awk '
# Print list of word frequencies
{
    for (i = 1; i <= NF; i++)
        freq[$i]++
}

END {
    for (word in freq)
        printf "%s\t%d\n", word, freq[word]
}' test.txtIf

Kuwait  UAE     Qatar   KSA     Jordan
Lebanon Egypt   Syria   Kuwait  Qatar

Syria   1
KSA     1
Lebanon 1
UAE     1
Qatar   2
Egypt   1
Jordan  1
Kuwait  2

Je tiens à expliquer, mais mon anglais n'est pas suffisant.
peut-être cet pourrait aider.

J'ai modifié le code pour illustrer le contenu de freq à chaque itération:

$cat freq.awk
#! /bin/ksh
awk '
# Print list of word frequencies
{
    for (i = 1; i <= NF; i++)
{
# Here loop variable i will contain values like 1, 2, 3 until last field of 
# Record which in your case is 5, so $i will behave like $1, $2, $3
# Following condition will lookup in array if key($i ie name of city in your case)
# Already exists in array or not

        if ( $i in freq )     
        print "Key(" $i "): is already there in array and its frequency or value is:  " freq[$i]

# In the 1st iteration of loop, $i($1) is equal to Kuwait, so freq[$i]
# Means freq[Kuwait], because you dont have any value associated to key Kuwait
# Therefor freq[$i] yeilds to zero and ++ operator increases it to 1

        freq[$i]++

# Print the record no., field no. value of key and freq associated to key, at each iteration of loop

        print "Record No." NR "\tField No: " i "\tValue of key: " $i "\tFrequency of word: " freq[$i]
}
print "\n"
}

END {
# Loop thru the whole array(freq) and find the associated value to each key
# Here word denotes key and freq[word] refres value associated to each key

    for (word in freq)
        printf "%s\t%d\n", word, freq[word]
}' abc.txt

$cat abc.txt
Kuwait  UAE     Qatar   KSA     Jordan
Lebanon Egypt   Syria   Kuwait  Qatar

$./freq.awk
Record No.1     Field No: 1     Value of key: Kuwait    Frequency of word: 1
Record No.1     Field No: 2     Value of key: UAE       Frequency of word: 1
Record No.1     Field No: 3     Value of key: Qatar     Frequency of word: 1
Record No.1     Field No: 4     Value of key: KSA       Frequency of word: 1
Record No.1     Field No: 5     Value of key: Jordan    Frequency of word: 1


Record No.2     Field No: 1     Value of key: Lebanon   Frequency of word: 1
Record No.2     Field No: 2     Value of key: Egypt     Frequency of word: 1
Record No.2     Field No: 3     Value of key: Syria     Frequency of word: 1
Key(Kuwait): is already there in array and its frequency or value is:  1
Record No.2     Field No: 4     Value of key: Kuwait    Frequency of word: 2
Key(Qatar): is already there in array and its frequency or value is:  1
Record No.2     Field No: 5     Value of key: Qatar     Frequency of word: 2


Syria   1
KSA     1
Lebanon 1
UAE     1
Qatar   2
Egypt   1
Jordan  1
Kuwait  2

Shereenmotor, Merci beaucoup pour votre réponse détaillée.