Being given requirements little bits at a time, instead of giving us all of the requirements up front wastes our time and is likely to introduce significant delays in getting the results you want...

You explicitly state that the lower bound for range 1 is 0 and in2nix4life's script assumes that $5 will never contain a negative number. (If a negative number is given, in2nix4life's script will print the range value for the previous input line.)

You said that field widths will vary but in2nix4life's script assumed upper bounds of 40 characters for column 1 and 10 characters for column 5.

The following script seems to meet your updated requirements (and it should be clear how to add additional domains with different sets of ranges). This script reads the file twice; the 1st pass gets the maximum field widths present in your input, and the 2nd pass prints the results. If column 5's value is less than zero, this script will print -1 for the range code. You can ignore that test if you know no input will ever have a negative value, or you can do something else where that test occurs if you want to print an error message, just remove that line's data from the output, or take some other action.

Code:

/usr/xpg4/bin/awk '
BEGIN {#ERE to match domain     Range 0 max     Range 1 max
        dom[0] = "^EH\.";       rm[0,0] = 10;   rm[0,1] = 20     
        dom[1] = "^ERP\.";      rm[1,0] = 300;  rm[1,1] = 500     
        dom[2] = ".*";          rm[2,0] = 10;   rm[2,1] = 100       
        ndom=3
        # determine # of columns needed to print range values...  
        for(i = 0; i < ndom; i++) {    
                if(length(rm[i,0]) > mr0) mr0 = length(rm[i,0])  
                if(length(rm[i,1]) > mr1) mr1 = length(rm[i,1])   
        }
}
FNR == NR {
        # 1st pass through the file; get max lengths of fields 1 and 5    
        if(length($1) > m1) m1 = length($1)
        if(length($5) > m5) m5 = length($5)
        next
}
FNR == 1 {
        # 1st line in 2nd pass; create format string to be used...  
        fmt = sprintf("%%-%ds%%%dd%%3d%%%dd%%%dd\n",
                m1, m5 + 1, mr0 + 1, mr1 + 1)
}
{       # 2nd pass; print the results...
        for(i = 0; i < ndom; i++) {
                if($1 ~ dom[i]) {
                        r = ($5 > rm[i,0]) + ($5 > rm[i,1])
                        break
                }        }
        if($5 < 0) r = -1
        printf(fmt, $1, $5, r, rm[i,0], rm[i,1])
}' file file

Since you said you're doing this on a Solaris system, I specified /usr/xpg4/bin/awk (instead of the default /bin/awk or /usr/bin/awk) as the utility to use to run this awk script. If you want to run it on another system, change the first line of the script from:

Code:

/usr/xpg4/bin/awk '

to just:

Code:

awk '